/* Job Satisfaction example */

options ls=80 nocenter nodate;

data collar;
input manager $ super $ worker $ count @@;
datalines;
bad low low 103 bad low high 87 bad high low 32 bad high high 42
good low low 59 good low high 109 good high low 78 good high high 205
;
proc sort; by manager;
 
 /*saturated model */
proc genmod order=data;
 class manager super worker;
 model count = manager super worker manager*super manager*worker super*worker manager*super*worker /link=log dist=poi obstats;
 title 'Saturated model:  (MSW)';
run;
 
 /* complete independence */
 proc genmod order=data;
 class manager super worker;
 model count = manager super worker /link=log dist=poi obstats;
 title 'Complete independence model:  (M,S,W)';
run;


/* joint independence of (MS,W) */
proc genmod order=data;
 class manager super worker;
 model count = manager super worker manager*super /link=log dist=poi obstats;
 title 'Joint Independence:  (MS,W)';
run;

/* joint independence of (MW,S) */
proc genmod order=data;
 class manager super worker;
 model count = manager super worker manager*worker /link=log dist=poi obstats;
 title 'Joint Independence:  (MW,S)';
run;

/* joint independence of (SW,M) */
proc genmod order=data;
 class manager super worker;
 model count = manager super worker super*worker /link=log dist=poi obstats;
 title 'Joint Independence:  (SW,M)';
run;


 /* conditional independence (MS,MW) */
proc genmod order=data;
 class manager super worker;
 model count = manager super worker manager*super manager*worker /link=log dist=poi obstats;
 title 'Conditional Independence:  (MS,MW)';
run;

/* conditional independence (MS,SW) */
proc genmod order=data;
 class manager super worker;
 model count = manager super worker manager*super super*worker /link=log dist=poi obstats;
 title 'Conditional Independence:  (MS,SW)';
run;

/* conditional independence (MW, SW) */
proc genmod order=data;
 class manager super worker;
 model count = manager super worker manager*worker super*worker /link=log dist=poi obstats;
 title 'Conditional Independence:  (MW, SW)';
run;


/* homogeneous associations */ 
proc genmod order=data data=collar ;
 class manager super worker;
 model count = manager super worker  manager*super manager*worker worker*super /link=log dist=poi obstats;
 title 'Homogeneous Association:  (MS,MW,SW)';
run;

;