/* Analysis of a 3-way table Berkeley Admissions data using PROC GENMOD*/
/* Fitting various log-linear models*/
/* For a related analysis via PROC FREQ see berkeley.sas*/
options nocenter nodate nonumber linesize=80;
data berkeley;
   input D $ S $ A $ count;
   cards;
DeptA  Male    Reject  313
DeptA  Male    Accept  512
DeptA  Female  Reject   19
DeptA  Female  Accept   89
DeptB  Male    Reject  207
DeptB  Male    Accept  353
DeptB  Female  Reject    8
DeptB  Female  Accept   17
DeptC  Male    Reject  205
DeptC  Male    Accept  120
DeptC  Female  Reject  391
DeptC  Female  Accept  202
DeptD  Male    Reject  278
DeptD  Male    Accept  139
DeptD  Female  Reject  244
DeptD  Female  Accept  131
DeptE  Male    Reject  138
DeptE  Male    Accept   53
DeptE  Female  Reject  299
DeptE  Female  Accept   94
DeptF  Male    Reject  351
DeptF  Male    Accept   22
DeptF  Female  Reject  317
DeptF  Female  Accept   24
;

/*saturated model via PROC FREQ*/
proc freq data=berkeley order=data;
weight count;
tables A*D*S/cmh chisq relrisk expected nocol norow;
tables D*S/chisq relrisk;
run;

/*saturated model DSA, two different ways of fitting it*/
proc genmod data=berkeley order=data;
class D S A;
model count = D*S*A / dist=poisson link=log;
model count= D S A D*S D*A S*A D*S*A/dist=poisson link=log;
run;

/*model of complete independence*/
proc genmod data=berkeley order=data;
class D S A;
model count = D S A / dist=poisson link=log;
run;

/* joint independence of D and S from A*/
proc genmod data=berkeley order=data;
class D S A;
model count = D S A D*S / dist=poisson link=log;
run;

/*you can fill in the rest of the models*/