The following program is missing a semicolon on the comment statement just before the DATA statement:

OPTIONS PS = 58 LS = 72 NODATE NONUMBER;
*Read in the trees data set
DATA trees;
    input type $ 1-16 circ_in hght_ft crown_ft;
	DATALINES;
oak, black        222 105 112
hemlock, eastern  149 138  52
ash, white        258  80  70
cherry, black     187  91  75
maple, red        210  99  74
elm, american     229 127 104
;
RUN;

Output

   OPTIONS PS = 58 LS = 72 NODATE NONUMBER;
   *Read in the trees data set
   DATA trees;
       input type $ 1-16 circ_in hght_ft crown_ft;
       -----
       180

ERROR 180-322: Statement is not valid or it is used out of proper order.

       DATALINES;
       ---------
       180

ERROR 180-322: Statement is not valid or it is used out of proper order.

   oak, black        222 105 112
   ---
   180
ERROR 180-322: Statement is not valid or it is used out of proper order.

   hemlock, eastern  149 138  52
   ash, white        258  80  70
   cherry, black     187  91  75
   maple, red        210  99  74
   elm, american     229 127 104
   ;

   RUN;

When you omit a semicolon, SAS reads the statement that lacks the semicolon, plus the following statement, as one long statement. In this case, DATA trees become a part of the comment statement. Therefore, SAS thinks that the program doesn't contain a DATA statement. Therefore, SAS underlines the INPUT keyword and complains that it doesn't appear as a valid part of a SAS program. Launch and run   the SAS program, and review the contents of the log window to see the message that submitting such a program causes.

This example shows the same program as above, but now the semicolon is missing at the end of the DATA statement:

OPTIONS PS = 58 LS = 72 NODATE NONUMBER;
  *Read in the trees data set;
  DATA trees
    input type $ 1-16 circ_in hght_ft crown_ft;
	DATALINES;
oak, black        222 105 112
hemlock, eastern  149 138  52
ash, white        258  80  70
cherry, black     187  91  75
maple, red        210  99  74
elm, american     229 127 104
;
RUN;

Output

   OPTIONS PS = 58 LS = 72 NODATE NONUMBER;
   *Read in the trees data set;
   DATA trees
       input type $ 1-16 circ_in hght_ft crown_ft;
                  -
                  22
                  200
                    -
                    22
                    76
ERROR 22-322: Syntax error, expecting one of the following: a name,
              a quoted string, (, /, ;, _DATA_, _LAST_, _NULL_.

ERROR 200-322: The symbol is not recognized and will be ignored.

ERROR 76-322: Syntax error, statement will be ignored.

       DATALINES;

NOTE: The SAS System stopped processing this step because of errors.
NOTE: DATA statement used (Total process time):
      real time           0.01 seconds
      cpu time            0.01 seconds

   ;


   RUN;

In this case, the INPUT statement becomes a part of the DATA statement. Therefore, SAS expects to see valid data set names or options, not a dollar sign ($) or column numbers. Launch and run   the SAS program, and review the contents of the log window to see the message that submitting such a program causes. You should see that SAS reports that it found a syntax error, and then goes on to tell you what it expected to find in the DATA statement.

The next example shows the same program as above, in which the semicolon is missing at the end of the DATA statement. However, now the DATASTMTCHK system option has been added to the code:

OPTIONS DATASTMTCHK = ALLKEYWORDS;
*Read in the trees data set;
DATA trees
    input type $ 1-16 circ_in hght_ft crown_ft;
	DATALINES;
oak, black        222 105 112
hemlock, eastern  149 138  52
ash, white        258  80  70
cherry, black     187  91  75
maple, red        210  99  74
elm, american     229 127 104
;
RUN;

Output

   OPTIONS DATASTMTCHK = ALLKEYWORDS;
   *Read in the trees data set;
   DATA trees
       input type $ 1-16 circ_in hght_ft crown_ft;
       -----      -
       57         22
                  200
                    -
                    22
                    76
ERROR 57-185: INPUT is not allowed in the DATA statement when option
              DATASTMTCHK=ALLKEYWORDS.  Check for a missing semicolon
              in the DATA statement, or use DATASTMTCHK=NONE.

ERROR 22-322: Syntax error, expecting one of the following: a name,
              a quoted string, (, /, ;, _DATA_, _LAST_, _NULL_.

ERROR 200-322: The symbol is not recognized and will be ignored.

ERROR 76-322: Syntax error, statement will be ignored.

       DATALINES;

NOTE: The SAS System stopped processing this step because of errors.
NOTE: DATA statement used (Total process time):
      real time           0.01 seconds
      cpu time            0.01 seconds

   ;

   RUN;

The DATASTMTCHK system option controls what names you can use for SAS data sets in a DATA statement. By default, the option is set so that you cannot use the words MERGE, RETAIN, SET, or UPDATE as a SAS data set name. You can instead make all SAS keywords invalid SAS data set names by setting the DATASTMTCHK option to ALLKEYWORDS, as is done in the above program. Launch and run   the SAS program, and review the log window to see the message SAS displays when the DATASTMTCHK option is invoked.

We've looked at three examples now in which a semicolon is missing. Do you think it is fair to say that the moral of the story is that you can usually find the statement that lacks the semicolon by working backwards in your program starting with the keywords that are underscored in the error message? Once you've found the location where the semicolon is missing, simply add a semicolon, resubmit your corrected program, and check the SAS log again to make sure that there are no other errors.

The following example illustrates the "Error: Invalid option" message SAS displays in the log window when you attempt to use an option that is invalid:

DATA trees (ROP = crown_ft);
    input type $ 1-16 circ_in hght_ft crown_ft;
	DATALINES;
oak, black        222 105 112
hemlock, eastern  149 138  52
ash, white        258  80  70
cherry, black     187  91  75
maple, red        210  99  74
elm, american     229 127 104
;
RUN;

Output

   DATA trees (ROP = crown_ft);
               ---
               22
ERROR 22-7: Invalid option name ROP.

     input type $ 1-16 circ_in hght_ft crown_ft;
     DATALINES;

NOTE: The SAS System stopped processing this step because of errors.
NOTE: DATA statement used (Total process time):
    real time           0.01 seconds
    cpu time            0.03 seconds

   ;

   RUN;

We'll learn down the road that we can use the DATA statement's DROP= option when we want SAS to drop a variable from the program data vector before writing observations to the output data set. In the above program, we attempt to drop the variable crown_ft from the output trees data set. As you can see, though, we forgot to type the starting D. SAS doesn't know that though ... it thinks we want to use the nonexistent ROP= option. Launch and run   the SAS program, and review the log window to see the message SAS displays in this situation.

The following example illustrates the "Error: Syntax error" message SAS displays in the log window when your input statement is incorrect:

DATA trees;
    input *type $ 1-16 circ_in hght_ft crown_ft;
	DATALINES;
oak, black        222 105 112
hemlock, eastern  149 138  52
ash, white        258  80  70
cherry, black     187  91  75
maple, red        210  99  74
elm, american     229 127 104
;
RUN;

Output

   DATA trees;
       input *type $ 1-16 circ_in hght_ft crown_ft;
             -
             22
             200
ERROR 22-322: Syntax error, expecting one of the following: a name, arrayname, #, (, +, /, //, ;, @, @@.

ERROR 200-322: The symbol is not recognized and will be ignored.

       DATALINES;

NOTE: The SAS System stopped processing this step because of errors.
WARNING: The data set WORK.TREES may be incomplete.  When this step was stopped there were 0 observations and 4 variables.
NOTE: DATA statement used (Total process time):
    real time           0.02 seconds
    cpu time            0.01 seconds

   ;

   RUN;

Of course, what is really going on here is that we are trying to use an invalid variable name. Recall that variable names must begin with a letter or an underscore. Trying to specify a variable name *type thus causes SAS to hiccup. SAS does not recognize *type as a valid variable name and therefore provides a list of items SAS would expect to follow the INPUT keyword. Launch and run   the SAS program, and review the log window to see the message SAS displays in this situation.

The following example illustrates the "Error: Statement is not valid or it is used out of proper order" message SAS displays in the log window when you attempt to use a statement that is not valid:

DATA trees;
    input type $ 1-16 circ_in hght_ft crown_ft;
	DATALINES;
oak, black        222 105 112
hemlock, eastern  149 138  52
ash, white        258  80  70
cherry, black     187  91  75
maple, red        210  99  74
elm, american     229 127 104
;
RUN;
PROC PRINT;
     set type circ_in hght_ft;
RUN;

Output

   DATA trees;
       input type $ 1-16 circ_in hght_ft crown_ft;
       DATALINES;

NOTE: The data set WORK.TREES has 6 observations and 4 variables.
NOTE: DATA statement used (Total process time):
    real time           0.01 seconds
    cpu time            0.01 seconds

   ;
   RUN;

   PROC PRINT;
NOTE: Writing HTML Body file: sashtml.htm
        set type circ_in hght_ft;
        ---
        180
ERROR 180-322: Statement is not valid or it is used out of proper order.
   RUN;

NOTE: The SAS System stopped processing this step because of errors.
NOTE: PROCEDURE PRINT used (Total process time):
    real time           0.51 seconds
    cpu time            0.32 seconds

Of course, instead of using the SET statement to tell SAS what variables we would like displayed, we should be using the VAR statement. Launch and run   the SAS program, and review the log window to see the message SAS displays in this situation.

Whether your program contains an invalid option, invalid name, or invalid statement, simply use the log messages to locate the problem and make the appropriate correction to your program. After you resubmit your corrected program, check the SAS log again to make sure there are no other errors.

As should be fairly obvious by the coloration of the code, the following program is missing a closing quotation mark in the PRINT procedure's first TITLE statement:

DATA trees;
    input type $ 1-16 circ_in hght_ft crown_ft;
	DATALINES;
oak, black        222 105 112
hemlock, eastern  149 138  52
ash, white        258  80  70
cherry, black     187  91  75
maple, red        210  99  74
elm, american     229 127 104
;
RUN;
PROC PRINT;
     var type circ_in hght_ft;
	 title 'Some trees in Kentucky
	 title2 'Division of Forestry';
RUN;

Output

   DATA trees;
   input type $ 1-16 circ_in hght_ft crown_ft;
   DATALINES;
NOTE: The data set WORK.TREES has 6 observations and 4 variables.
NOTE: DATA statement used (Total process time):
   real time           0.01 seconds
   cpu time            0.01 seconds
;
RUN;
PROC PRINT;
     var type circ_in hght_ft;
     title 'Some trees in Kentucky
     title2 'Division of Forestry';
RUN;

If you launch and run   the SAS program, you should see that no output is generated, and in the top blue bar of the SAS window, you should notice that the PRINT procedure continues to run:

That's because when SAS encountered the unbalanced quotation marks in the first TITLE statement, it continued to look for the closing quotation mark and in the process swallowed up the PRINT procedure's closing RUN statement.

Unfortunately, simply adding a quotation mark, and resubmitting your program typically does not solve the problem. SAS still considers the quotation marks to be unbalanced. (You might want to convince yourself that this is indeed true by adding the quotation mark to the end of the first TITLE statement and resubmitting the program.)

Instead, you must first cancel the errant program before you correct and resubmit the program. These are the specific steps that you need to take in this situation:

1. Anywhere in your program, type an asterisk followed by a quotation mark, a semicolon, and a RUN statement with a closing semicolon:

   *'; RUN;

2. Use your cursor to select just the line of code that you typed. Then, submit just that line of code by clicking on the running man  .

3. Delete the line of code that contains the asterisk followed by a quotation mark, a semicolon, and a RUN statement with a closing semicolon:

   *'; RUN;

4. Insert the missing quotation mark in the appropriate place in the program.
5. Submit   the corrected program.

You should go ahead and follow these steps for our program to convince yourself that the steps work. Then, when all is said and done, you should look at the log window to see the two warning messages that SAS displays about the "quoted-string has more than 262 characters" and "the TITLE statement is ambiguous due to invalid options or unquoted text."

Whenever SAS behaves in the way described in this section, the first thing you should suspect is unbalanced quotation marks. Then, you'll want to make sure you resolve the problem as soon as it occurs. Otherwise, it is likely that any subsequent programs that you submit in the current SAS session will generate errors.

The following program contains invalid values for the hght_ft variable in the first and third records of the instream data:

OPTIONS PS = 58 LS = 72 NODATE NONUMBER;
DATA trees;
    input type $ 1-16 circ_in hght_ft crown_ft;
	DATALINES;
oak, black        222 1O5 112
hemlock, eastern  149 138  52
ash, white        258  8O  70
cherry, black     187  91  75
maple, red        210  99  74
elm, american     229 127 104
;
RUN;
PROC PRINT data = trees;
    title 'Trees in Kentucky';
RUN;

Output

   OPTIONS PS = 58 LS = 72 NODATE NONUMBER;
   DATA trees;
       input type $ 1-16 circ_in hght_ft crown_ft;
       DATALINES;

NOTE: Invalid data for hght_ft in line 5 23-25.
RULE:      ----+----1----+----2----+----3----+----4----+----5----+----6-
         oak, black        222 1O5 112
type=oak, black circ_in=222 hght_ft=. crown_ft=112 _ERROR_=1 _N_=1
NOTE: Invalid data for hght_ft in line 7 24-25.
         ash, white        258  8O  70
type=ash, white circ_in=258 hght_ft=. crown_ft=70 _ERROR_=1 _N_=3
NOTE: The data set WORK.TREES has 6 observations and 4 variables.
NOTE: DATA statement used (Total process time):
    real time           0.01 seconds
    cpu time            0.01 seconds

   ;
   RUN;
   PROC PRINT data = trees;
NOTE: Writing HTML Body file: sashtml.htm
       title 'Trees in Kentucky';
   RUN;

NOTE: There were 6 observations read from the data set WORK.TREES.
NOTE: PROCEDURE PRINT used (Total process time):
    real time           0.46 seconds
    cpu time            0.28 seconds

First, note that the zero in the "105" and "80" values in the first and third records are a little rounder than the zero that appears, say, in the "70" in the third record. That's because the "105" and "80" actually contain the letter O rather than the number 0. That means that SAS is going to have a problem reading them in, because it is expecting all of the data values for the hght_ft variable to be numeric.

Then, launch and run   the SAS program, and review the log window to see the Invalid data notes that SAS displays in this situation. Let's focus for a minute on just one of the messages:

NOTE: Invalid data for hght_ft in line 5 23-25.
RULE:      ----+----1----+----2----+----3----+----4----+----5----+----6-
         oak, black        222 1O5 112
type=oak, black circ_in=222 hght_ft=. crown_ft=112 _ERROR_=1 _N_=1

The first line tells us where the problem occurred. Specifically, it states that SAS got stuck on the hght_ft variable in columns 23 to 25 of line 220 of the raw data file that SAS was trying to read. In this case of course we are reading instream data, so that line 220 is a function of the line the record sits on within your SAS session. In fact, it is most likely that the line number you obtained differs from 220. In any case, it certainly helps to know that the problem occurs in columns 23 to 25 where SAS is expecting to read in a data value for the numeric variable hght_ft.

The second line is a type of ruler with columns as increments. The number 1 marks the tenth column, the number 2 the twentieth column, and so on. Below the ruler, SAS displays the actual line of raw data so that we can identify the culprit ourselves. Beginning in column 23, we see that the value "1O5" is the problem. The error at this point is typically found to be obvious, as is the case here.

In the fourth and final line, SAS displays the values of each variable for that observation as SAS reads it. You can see that SAS set hght_ft to missing and the automatic variable _ERROR_ to 1, denoting that an error occurred while reading in the record. If you review the output from the PRINT procedure:

you can see where the hght_ft variable is set to missing in the first and third observations, but not in the others. In general, invalid data notes affect only the observations in which the errors are found. Now, of course, it is possible that all of your observations might have data values that are inconsistent with your INPUT statement. That might happen:

• if you forgot to use a dollar sign ($) to tell SAS that a variable is a character variable
• if your INPUT statement contains incorrect column numbers for one of the variables so that SAS tries to read blank as numeric values
• if you use special characters, such as a tab space, in numeric data
• if you use the wrong informat such as mmddyy8. instead of ddmmyy8.

Other reasons why your log window might contain invalid data notes include:

• if you are using list input to read two periods in a row with no space in between
• if your data contains invalid dates, such as February 30, and you are trying to read them in with a date informat
• if you are using list input to read data containing missing values, but no placeholders, causing SAS to read the next available data value

That's about it for invalid data. In short, the moral of the story is if your log window contains an invalid data note (or two or three or ...), suspect that one of the above things is awry. Use the location specified in the invalid data note to help ferret out the problem.

The following example illustrates the "Note: Variable is uninitialized" and "Error: Variable not found" messages SAS displays in the log window to warn you of such problems:

OPTIONS PS = 58 LS = 72 NODATE NONUMBER;
DATA trees;
    input type $ 1-16 circ_in hght_ft crown_ft;
	volume = (0.319*hght)*(0.0000163*circ_in**2);
	DATALINES;
oak, black        222 105 112
hemlock, eastern  149 138  52
ash, white        258  80  70
cherry, black     187  91  75
maple, red        210  99  74
elm, american     229 127 104
;
RUN;
PROC PRINT data = trees;
    var type height circ_in volume;
RUN;

Output

   OPTIONS PS = 58 LS = 72 NODATE NONUMBER;
   DATA trees;
       input type $ 1-16 circ_in hght_ft crown_ft;
       volume = (0.319*hght)*(0.0000163*circ_in**2);
       DATALINES;

NOTE: Variable hght is uninitialized.
NOTE: Missing values were generated as a result of performing an
    operation on missing values.
    Each place is given by: (Number of times) at (Line):(Column).
    6 at 20:20
NOTE: The data set WORK.TREES has 6 observations and 6 variables.
NOTE: DATA statement used (Total process time):
    real time           0.01 seconds
    cpu time            0.01 seconds

   ;
   RUN;

   PROC PRINT data = trees;
       var type height circ_in volume;
ERROR: Variable HEIGHT not found.
   RUN;

NOTE: The SAS System stopped processing this step because of errors.
NOTE: PROCEDURE PRINT used (Total process time):
      real time           0.00 seconds
      cpu time            0.00 seconds

First, note that there are two places in which a variable name was misspecified in this program. In the calculation of volume in the DATA step, the height of the tree is referred to as hght rather than hght_ft in which the heights were actually stored. And, in the PRINT procedure, the height of the tree is referred to as height. Well, okay, so the programmer, is a little confused! Launch and run   the SAS program, and review the log window to see the two messages that SAS displays in this situation.

Common ways to "lose" variables include:

• misspelling a variable name
• using a variable that was dropped from the data set at some earlier time
• using the wrong data set
• committing a logic error, such as using a variable before it is created

If the source of the problem is not immediately obvious, submitting a CONTENTS procedure can often help you sniff out the problem. As you may recall from an earlier lesson, the CONTENTS procedure provides, among other things, the names of the variables contained in a SAS data set.

The following example shows what can happen if you are using list input, and your data file doesn't contain periods as placeholders for numeric missing values:

OPTIONS PS = 58 LS = 72 NODATE NONUMBER;
DATA trees;
    input treeID circ_in hght_ft crown_ft;
	DATALINES;
101 222 105 112
102 149 138 
103 258  80  70
104 187  91  
105 210  99  74
106 229 127 104
;
RUN;
PROC PRINT data = trees;
    title 'Tree data';
RUN;

Output

   OPTIONS PS = 58 LS = 72 NODATE NONUMBER;

   DATA trees;
       input treeID circ_in hght_ft crown_ft;
       DATALINES;

NOTE: SAS went to a new line when INPUT statement reached past the end
    of a line.
NOTE: The data set WORK.TREES has 4 observations and 4 variables.
NOTE: DATA statement used (Total process time):
    real time           0.01 seconds
    cpu time            0.00 seconds

   ;
   RUN;

   PROC PRINT data = trees;
       title 'Tree data';
   RUN;

NOTE: There were 4 observations read from the data set WORK.TREES.
NOTE: PROCEDURE PRINT used (Total process time):
    real time           0.00 seconds
    cpu time            0.01 seconds

First, review the data and note that tree numbers 102 and 104 are missing values for the crown_ft variable, with no periods serving as placeholders for the missing values. Then, launch and run   the SAS program, and review the log window to see the message SAS displays in this situation. If you review the output from the PRINT procedure:

you can see the effect on the output data set of SAS going to a new line to find the missing data. For example, for tree 102, when SAS went to the next line to look for the crown_ft value, it found the value 103, which was supposed to be the ID number for the next tree. Oh, if SAS could only read our mind!

One way of solving the problem of SAS going to the next line to look for the missing data values is to insert missing value periods (.) as placeholders. That solution would work for this small data set, but it wouldn't work when you are working with a large data set with thousands of records. In that case, the simplest thing to do to prevent SAS from going to a new line looking for data is to use the MISSOVER option of the INFILE statement. The MISSOVER option tells SAS to assign missing values to any variables for which there was no data instead of proceeding to the next line looking for the values. The following example illustrates using the MISSOVER option:

OPTIONS PS = 58 LS = 72 NODATE NONUMBER;
DATA trees;
    INFILE DATALINES MISSOVER;
    input treeID circ_in hght_ft crown_ft;
	DATALINES;
101 222 105 112
102 149 138 
103 258  80  70
104 187  91  
105 210  99  74
106 229 127 104
;
RUN;
PROC PRINT data = trees;
    title 'Tree data';
RUN;

Output

   OPTIONS PS = 58 LS = 72 NODATE NONUMBER;

   DATA trees;
       INFILE DATALINES MISSOVER;
       input treeID circ_in hght_ft crown_ft;
       DATALINES;

NOTE: The data set WORK.TREES has 6 observations and 4 variables.
NOTE: DATA statement used (Total process time):
    real time           0.01 seconds
    cpu time            0.00 seconds

   ;
   RUN;

   PROC PRINT data = trees;
       title 'Tree data';
   RUN;

NOTE: There were 6 observations read from the data set WORK.TREES.
NOTE: PROCEDURE PRINT used (Total process time):
      real time           0.00 seconds
      cpu time            0.00 seconds

First, note that the only thing that differs between this program and the previous one is the presence of the INFILE statement with the MISSOVER option. Then, launch and run   the SAS program, and review the output from the PRINT procedure to confirm that SAS correctly reads in the data when the MISSOVER option is invoked:

You might also want to take a look at the log window to verify that this time SAS did not display a NOTE about going to a new line when it reached past the end of a line.

The following example illustrates how SAS propagates missing values. That is, for some calculations, SAS assigns a variable a missing value if any of the values contributing to the calculation are missing. In this example, SAS generates missing values when attempting to calculate the volume of the tree when either the height or the circumference is missing:

OPTIONS PS = 58 LS = 72 NODATE NONUMBER;
DATA trees;
    input type $ 1-16 circ_in hght_ft crown_ft;
	volume = (0.319*hght_ft)*(0.0000163*circ_in**2);
	DATALINES;
oak, black        222   . 112
hemlock, eastern  .   138  52
ash, white        258  80  70
cherry, black     187  91  75
maple, red        210  99  74
elm, american     229 127 104
;
RUN;
PROC PRINT data = trees;
    title 'Tree data';
RUN;

Output

   OPTIONS PS = 58 LS = 72 NODATE NONUMBER;

   DATA trees;
       input type $ 1-16 circ_in hght_ft crown_ft;
       volume = (0.319*hght_ft)*(0.0000163*circ_in**2);
       DATALINES;

NOTE: Missing values were generated as a result of performing an
    operation on missing values.
    Each place is given by: (Number of times) at (Line):(Column).
    1 at 73:20   1 at 73:40   1 at 73:48
NOTE: The data set WORK.TREES has 6 observations and 5 variables.
NOTE: DATA statement used (Total process time):
    real time           0.00 seconds
    cpu time            0.01 seconds

   ;
   RUN;

   PROC PRINT data = trees;
       title 'Tree data';
   RUN;

NOTE: There were 6 observations read from the data set WORK.TREES.
NOTE: PROCEDURE PRINT used (Total process time):
      real time           0.00 seconds
      cpu time            0.01 seconds

First, review the data and note that the first tree is missing a value for hght_ft and the second tree is missing a value for circ_in. Then, launch and run   the SAS program, and review the log window to see the "missing values generated" message SAS displays in this situation. If you review the output from the PRINT procedure:

you can see that SAS did indeed assign a missing value to the volume variable for the first two observations.

When you are working with a large data set, it can be difficult to locate all the places in which a missing value was generated based on a calculation. In that case, you'll probably want to use a selecting IF statement to find the missing values. The following example illustrates using an IF statement to find the observations that are assigned a missing value for the newly calculated variable volume:

OPTIONS PS = 58 LS = 72 NODATE NONUMBER;
DATA trees;
    input type $ 1-16 circ_in hght_ft crown_ft;
	volume = (0.319*hght_ft)*(0.0000163*circ_in**2);
	if volume = .;
	DATALINES;
oak, black        222   . 112
hemlock, eastern  .   138  52
ash, white        258  80  70
cherry, black     187  91  75
maple, red        210  99  74
elm, american     229 127 104
;
RUN;
PROC PRINT data = trees;
    title 'Trees with Missing Volumes';
RUN;

Output

First, note that the only thing that differs between this program and the previous one is the presence of the IF statement. Then, launch and run   the SAS program, and review the output from the PRINT procedure to see the two observations for which the volume is deemed missing.