The DATA step in the following program uses the OBS= option to tell SAS to create a temporary data set called back by selecting the first 25 observations from the permanent background data set icdb.back:

OPTIONS PS=58 LS=80 NODATE NONUMBER;
DATA back;
    set icdb.back (obs=25);
RUN;
PROC PRINT data=back;
    title 'A Subset of the Background Data Set';
RUN;

Output

The program is pretty straightforward. The main thing to keep in mind is that you have to enclose the OBS= option in parentheses.

If you haven't already done so, download and save the background data set (click to save!) to a convenient location on your computer. Then, launch the SAS program, and edit the LIBNAME statement so that it reflects the location in which you've saved the data set. Then, run   the SAS program, and review the output from the PRINT procedure to familiarize yourself with the data set.

The following program uses the SET statement's FIRSTOBS= and OBS= options to tell SAS to include fourteen observations — observations 7, 8, 9, ..., and 20 — from the permanent icdb.back data set in the temporary back data set:

LIBNAME icdb 'C:\yourdrivename\Stat481WC\02datastep\sasndata';
DATA back1;
	set icdb.back (FIRSTOBS=7 OBS=20);
RUN;
 
PROC PRINT data=back1;
	title 'Output Dataset: BACK1';
RUN;

Output

Launch the SAS program, and edit the LIBNAME statement so that it reflects the location in which you saved the background data set. Then, run   the SAS program, and review the output from the PRINT procedure. Compare the output to the output of that from the previous example to convince yourself that the temporary data set back1 indeed contains fourteen observations — observations 7, 8, ..., 20 in the original background data set.

Rather than using the KEEP= option on the SET statement, you can use the KEEP= option on the DATA statement. The following program tells SAS to keep four variables — subj, v_date, b_date, and age — when writing to the output data set called back2a:

DATA back2a (keep = subj v_date b_date age);
    set back1;
    age = (v_date - b_date)/365;  * Calculate AGE in years;
    format age 4.1;
RUN;
PROC PRINT data=back2a;
    title 'Output Dataset: BACK2A';
RUN;

Output

The DATA statement's KEEP= option is used to tell SAS to write four variables — subj, v_date, b_date, and age — from the program data vector at the end of each iteration of the DATA step to the back2a data set. As before, the KEEP= option must be placed in parentheses and follow the name of the data set from you which you want SAS to select variables. The list of variables that you specify to keep must be separated by at least one blank space.

Launch and run   the SAS program, and review the output from the PRINT procedure to convince yourself that the temporary data set back2a is identical to the back2 data set created in Example 2.3. That is, the back2a data set, like the back2 data set, contains the four kept variables (subj, v_date, b_date, and age).

Rather than using the DROP= option on the SET statement, you can use the DROP= option on the DATA statement. The following program tells SAS to drop nine variables — r_id, race, ..., and income — when writing to the output data set back3a:

DATA back3a (drop = r_id race ethnic relig mar_st
		ed_level emp_st job_chng income);
	set back1;
RUN;
 
PROC PRINT data=back3a;
	title 'Output Dataset: BACK3A';
RUN;

Output

The DATA statement's DROP= option tells SAS to drop nine variables — r_id, race, ethnic, relig, mar_st, ed_level, emp_st, job_chng, and income — before writing the contents of the program data vector into the back3a data set. Therefore, the program data vector starts out with sixteen data set variables, but only writes seven of them to the back3a data set. As before, the DROP= option must be placed in parentheses and follow the name of the data set from you that you want SAS to exclude variables. The list of variables that you specify to drop must be separated by at least one blank space.

Launch and run   the SAS program. Review the output from the PRINT procedure to convince yourself that the back3a data set, just like the back3 data set, contains the seven variables that were not dropped from the data set.

The following program illustrates the use of the WHERE= option to select observations from a SAS data set that meet a certain condition. Because the WHERE= option is attached to the DATA statement, the selection process takes place as SAS writes the data from the program data vector to the output data set:

LIBNAME icdb 'C:\yourdrivename\Stat481WC\02datastep\sasndata';
DATA temple (where = (int(subj/10000)=23)) 
		okla (where = (int(subj/10000)=31));
	set icdb.back;
	drop r_id race ethnic relig mar_st ed_level 
		emp_st job_chng income;
RUN;

PROC PRINT data=temple;
	title 'Output Dataset: TEMPLE';
RUN;

PROC PRINT data=okla;
	title 'Output Dataset: OKLA';
RUN;

Output

Well, it's not really that simple. This program also illustrates the use of the WHERE= option to divide a large data set up into smaller data sets, based on the values of a certain variable. As you can see, there are actually two data set names — temple and okla — appearing in the DATA statement. That tells SAS that we want to create two data sets within this one DATA step. One data set, temple, should contain only those subjects enrolled at Temple University, while the other data set, okla, should contain only those subjects enrolled at the University of Oklahoma. Accomplishing that requires a bit of understanding about the subject number used in the ICDB Study, as well as the functionality of the INT function:

• The variable subj contains a six-digit subject number. The first two digits of the subject number indicate the location where the subject was enrolled. If the first two digits of the subject id number are 23, then the subject was enrolled at Temple University. If the first two digits of the subject id number are 31, the subject was enrolled at the University of Oklahoma.
• You might recall that the INT function — that is, the integer function— returns the integer part of the expression contained within parentheses. So, if the subject number is 230007, then int(subj/10000) = int(23.0007) = 23, the location id for Temple University.

Pay particular attention to the syntax of the WHERE= option ... it can trip you up if you aren't careful. The entire WHERE= option must be contained in parentheses immediately following the data set to which you want the condition to apply. The condition itself is also placed in parentheses. So, in general, the syntax, when applied to a DATA statement, should look like this:

DATA dsname (WHERE = (condition));

where dsname is the data set name and condition is the condition that you want SAS to evaluate when selecting the observations.

Now, before running the program, change the directory in the LIBNAME statement so that it reflects the location in which you have saved the background data set. After you've edited the LIBNAME statement, run   the SAS program. Review the output to convince yourself that the temporary data set temple contains the observations in the ICDB background data set that correspond to subjects enrolled at Temple University, while the temporary data set okla contains the observations that correspond to subjects enrolled at the University of Oklahoma. Also note that the DROP statement applies to both of the output data sets. The excluded variables are in neither temple nor okla.

A few more comments. When you use the WHERE= option, the condition applies only to the data set which immediately precedes it. Alternatively, you can use a WHERE statement, in which the condition applies to all of the input data sets. (In the next two lessons, we'll learn more about having more than one input data set.) Also, beware that the WHERE= option cannot be used at the same time as the FIRSTOBS= or OBS= options.

The following program illustrates the efficient use of the WHERE= option in the SET statement. Because the WHERE= option appears in the SET statement, the selection process takes place as SAS reads in the observations from the icdb.back data set:

LIBNAME icdb 'C:\yourdrivename\Stat481WC\02datastep\sasndata';
DATA temple2;
	set icdb.back (where = (int(subj/10000)=23));
	drop r_id race ethnic relig mar_st ed_level emp_st job_chng income;
RUN;

PROC PRINT data = temple2;
	title 'Output Dataset: TEMPLE2';
RUN;

Output

Before running the program, change the directory in the LIBNAME statement so that it reflects the location in which you have saved the background data set. After you've edited the LIBNAME statement, run   the SAS program. Review the output from the PRINT procedure. Convince yourself that the temple2 data set contains the observations in the ICDB background data set that correspond to subjects enrolled at Temple University.

The following program illustrates the use of the RENAME= option in the SET statement. Specifically, the variable sex is changed to gender, and b_date is changed to birth when the program data vector is created:

DATA back7 (keep = subj gender v_date birth age);
	set back3 (rename=(sex=gender b_date=birth));
	age = (v_date - birth)/365;   *MUST use NEW name for date of birth;
RUN;
 
PROC PRINT data=back7;
	title 'Output Dataset: BACK7';
RUN;

Output

Because the RENAME= option appears in the SET statement, SAS no longer recognizes the variable name sex as the gender, nor b_date as the birth date, of the subject. Instead, SAS recognizes the variable names gender and birth. Hence, when we subsequently calculate the subjects' ages (age) in the DATA step, we must refer to the new variable name birth.

Again, pay particular attention to the syntax of the RENAME= option ... it too can be tricky. The entire RENAME= option must be contained in parentheses immediately following the data set to which you want the name changes to apply. The variable names must also be placed in parentheses. So, in general, the syntax, when applied to a DATA statement, should look like this:

DATA dsname (RENAME = (o1=n1 o2=n2 ...));

where dsname is the data set name and o1 and o2 are the old variable names, and n1 and n2 are the new variable names.

Launch and run   the SAS program. Review the output from the PRINT procedure. Convince yourself that the variable names sex and b_date have been changed as advertised to gender and birth, respectively. Also, verify that the ages of the subjects have been calculated appropriately. Then, in the SAS program, change the variable name birth back to the variable name b_date, and re-run   the program. Does SAS indeed hiccup?

The following program illustrates the use of the RENAME= option, when it appears in the DATA statement. Specifically, the variable sex is changed to gender, and b_date is changed to birth when SAS writes the data to the output data set: 

DATA back8 (rename=(sex=gender b_date=birth)
		keep = subj sex v_date b_date age);
	set back3;
	age = (v_date - b_date)/365;      *MUST use OLD name for date of birth;
RUN;
 
PROC PRINT data=back8;
	title 'Output Dataset: BACK8';
RUN;

Output

Because the RENAME= option appears in the DATA statement, SAS only recognizes the variable names as they appear in the input data set back3. That is, for example, SAS recognizes the variable name b_date as the birth date of the subjects. Hence, when we subsequently calculate the subjects' ages in the DATA step, we must refer to the old variable name b_date. Also, note that the KEEP= option in the DATA statement must refer to the original variable names as they appear in the back3 data set.

This program also illustrates how to use more than one DATA step option at a time. Specifically, the RENAME= and KEEP= options are used to modify the back8 data set. As such, both options are placed within one set of parentheses immediately following the data set to which you want the changes to apply. Then, within those parentheses, the basic syntax for each option is followed.

Launch and run   the SAS program, and review the output from the PRINT procedure. Convince yourself that the variable names sex and b_date have been changed as advertised to gender and birth, respectively. Also, verify that the ages of the subjects have been calculated appropriately.

The following program illustrates using the IN= option when concatenating — that is, appending one data set to another data set. Although we'll take a closer look at concatenating two or more data sets in the next lesson, this example will give you a taste of what's to come:

DATA back9;
	set temple okla (in=okie);
	if okie = 1 then hospital = 31;
		else if okie = 0 then hospital = 23;
RUN;
 
PROC PRINT data=back9;
	title 'Output Dataset: BACK9';
RUN;

Output

The SET statement, in which both data set names temple and okla appear, tells SAS to concatenate the two data sets named temple and okla. That is, SAS will append the data set okla to the data set temple, so that the temporary data set back9 will contain 58 observations — 6 observations from temple and 52 observations from okla for a total of 58 observations.

The IN= option here tells SAS to create a temporary variable called okie that takes on the value 1 if the observation came from the okla data set and 0 if it did not. Therefore, the variable okie will equal 1 for the 52 observations from the data set okla and will equal 0 for the 6 observations from the data set temple. Because the indicator variable created by the IN= option is temporary, it goes away as soon as you leave the DATA step. For example, you can not print the indicator variable. To get around this, you can use the temporary variable to create a permanent variable. In this program, the temporary variable okie is used to create the permanent variable hospital.

Now, launch and run   the SAS program. Review the output from the PRINT procedure. Convince yourself that the temporary data set back9 does indeed contain 58 observations — 6 observations from temple and 52 observations from okla. Also, verify that the variable hospital was created as expected from the temporary variable okie.

The following program illustrates a cute programming trick when using the IN= option. Specifically, it illustrates how SAS assumes that you mean "if varname = 1" in an IF statement if you just say "if varname" where varname is the variable name specified in an IN= option. Therefore, you can use this fact to create helpful temporary variable names, such as indatasetname. Let's take a look:

DATA back10;
    set temple okla (in=inokie);
    if inokie then hospital = 31;
        else hospital = 23;
RUN;
 
PROC PRINT data=back10;
    title 'Output Dataset: BACK10';
RUN;

Output

Do you get it? The temporary variable inokie equals 1 for records coming from the okla data set and 0 for records coming from the temple data set. The IF statement does not (or need not) say "if inokie = 1 then hospital = 31." Instead, the IF statement says the much more English-sounding "if inokie then hospital = 31."

Launch and run   the SAS program. Review the output from the PRINT procedure, and convince yourself that the back10 data set has the same structure and contents as the back9 data set from the previous example.