Example 22.1.

The following SAS program reads five observations into a SAS data set called diet. Two of the variables — weight date (wt_date) and birth date (b_date) — are in mm/dd/yy format, and therefore SAS is told to read the dates using the mmddyy8. informat:

DATA diet;
	input subj 1-4 l_name $ 18-23 weight 30-32
    	+1 wt_date mmddyy8. @43 b_date mmddyy8.;
	DATALINES;
1024 Alice       Smith  1 65 125 12/1/05  01/01/60
1167 Maryann     White  1 68 140 12/01/05 01/01/59
1168 Thomas      Jones  2    190 12/2/05  06/15/60
1201 Benedictine Arnold 2 68 190 11/30/05 12/31/60
1302 Felicia     Ho     1 63 115 1/1/06   06/15/58
	;
RUN;
 
PROC PRINT data=diet;
	TITLE 'The unformatted diet data set';
RUN;

Output

First, note that the mmddyy8. informat must immediately follow the date's variable name. Here, it immediately follows wt_date, and then again follows b_date. Incidentally, the 8 in mmddyy8. defines, in general, the width of the informat. It tells SAS that the dates to be read into SAS contain as many as 8 positions. Here, two of the positions are taken up by forward slashes (/). You could alternatively use hyphens (-) or blank spaces between the mm dd and yy. Also, note that the period is a very important part of the informat name. Without it, SAS may attempt to interpret the informat as a variable name instead.

Then, launch and run   the SAS program, and review the resulting output to familiarize yourself with the contents of the diet data set. Note, in particular, the numeric values that are stored for the wt_date and b_date variables. As expected, the 01/01/60 birth date is stored as a 0, the 01/01/59 birthdate is stored as -365, and the 12/31/60 birthdate is stored as +365. Well, I guess the other thing that the output illustrates is that it is not enough just to tell SAS what informat to use to read in a date's value, you also have to tell SAS what format to use to display a date's value. If you don't, as you see here, the dates that are displayed are not particularly user-friendly!

Example 22.2.

The following SAS program is identical to the previous program, except a FORMAT statement has been added to tell SAS to display the wt_date and b_date variables in date7. format:

DATA diet;
input subj 1-4 l_name $ 18-23 weight 30-32
        +1 wt_date mmddyy8. @43 b_date mmddyy8.;
format wt_date b_date date7.;
DATALINES;
1024 Alice       Smith  1 65 125 12/1/05  01/01/60
1167 Maryann     White  1 68 140 12/01/05 01/01/59
1168 Thomas      Jones  2    190 12/2/05  06/15/60
1201 Benedictine Arnold 2 68 190 11/30/05 12/31/60
1302 Felicia     Ho     1 63 115 1/1/06   06/15/58
    ;
RUN;
 
PROC PRINT data=diet;
    title 'The formatted diet data set';
RUN;

Output

First, take note of the FORMAT statement in which the selected format date7. follows the two variables — wt_date and b_date — whose values we want to display as ddMonyy. Then, launch and run   the SAS program, and review the resulting output to convince yourself of the effect of the FORMAT statement.

Example 22.3

The following SAS program illustrates how you can treat date variables as any other numeric variable, and therefore can use the dates in numeric calculations. Assuming that individuals in the diet data set need to be weighed every 14 days, a new variable nxt_date, the anticipated date of the individual's next visit, is determined by merely adding 14 to the individual's current weight date (wt_date). Then, a crude estimate of each individual's age is also calculated by subtracting b_date from wt_date and dividing the resulting number of days by 365.25 to get an approximate age in years. And, the MEAN function is used to calculate avg_date, the average of each individual's birth and weight dates:

DATA diet;
    input  subj 1-4 l_name $ 18-23 weight 30-32
           +1 wt_date mmddyy8. @43 b_date mmddyy8.;
    nxt_date = wt_date + 14;
    age_wt = (wt_date - b_date)/365.25;
    avg_date = MEAN(wt_date, b_date);
    format wt_date b_date nxt_date avg_date date7. 
           age_wt 4.1; 
    DATALINES;
1024 Alice       Smith  1 65 125 12/1/05  01/01/60
1167 Maryann     White  1 68 140 12/01/05 01/01/59
1168 Thomas      Jones  2    190 12/2/05  06/15/60
1201 Benedictine Arnold 2 68 190 11/30/05 12/31/60
1302 Felicia     Ho     1 63 115 1/1/06   06/15/58
    ;
RUN;
 
PROC PRINT data=diet;
    title 'The diet data set with three new variables';
RUN;

Output

First, review the code to see how the three new variables — nxt_date, age_wt, and avg_date — are calculated using standard numeric expressions. You should also acknowledge that the calculation of avg_date is just a desperate attempt by a desperate instructor to illustrate the use of dates in a standard numeric function, and is otherwise probably fairly useless. Then, launch and run   the SAS program, and review the resulting output to convince yourself that the results of the calculations seem reasonable.

Example 22.4

The following SAS program illustrates again how you can treat date variables as any other numeric variable, and therefore can sort dates. The diet data set is sorted by nxt_date in ascending order so that the individuals whose next weigh-in date is closest in time appear first:

PROC SORT data = diet out = sorteddiet;
    by nxt_date;
RUN;
             
PROC PRINT data = sorteddiet;
    TITLE 'The diet data set sorted by nxt_date';
RUN;

Output

First, review the code, and then launch and run   the SAS program. Then, review the resulting output to convince yourself that the variable nxt_date is sorted as indeed claimed.

Example 22.5.

The following SAS program illustrates how to compare the values of a date variable, not to the values of some other date variable, but rather to a date constant. Specifically, the WHERE= option that appears on the DATA statement tells SAS to output to the diet data set only those individuals whose b_date is before January 1, 1960:

DATA diet (where = (b_date < '01jan1960'd));
	input subj 1-4 l_name $ 18-23 weight 30-32
    	+1 wt_date mmddyy8. @43 b_date mmddyy8.;
	format wt_date b_date date9.;
    DATALINES;
1024 Alice       Smith  1 65 125 12/1/05  01/01/60
1167 Maryann     White  1 68 140 12/01/05 01/01/59
1168 Thomas      Jones  2    190 12/2/05  06/15/60
1201 Benedictine Arnold 2 68 190 11/30/05 12/31/60
1302 Felicia     Ho     1 63 115 1/1/06   06/15/58
	;
RUN;
 
PROC PRINT data=diet;
	title 'Birthdays in the diet data set before 01/01/1960';
RUN;

Output

First, note the form of the SAS date constant:

'01jan1960'd

used in the WHERE= option. In general, a SAS date constant takes the form 'ddMONyyyy'd where dd denotes the day of the month (0, ..., 31), MON denotes the first three letters of the month, and yyyy denotes the four-digit year. The letter d that follows the date in single quotes tells SAS to treat the date string like a constant. Note that regardless of how you have informatted or formatted your SAS dates, the SAS date constant always takes the above form.

Now, launch and run   the SAS program. Then, review the resulting output to convince yourself that only those individuals whose birth date is before January 1, 1960, are included in the output diet data set. You might also want to note the difference between the date7. and date9. format. Previously, we saw that when you used the date7. format, your dates are displayed in ddMonyy format. Here, you can see that when you use the date9. format, your dates are displayed in ddMonyyyy format. (Incidentally, I think it is a good practice to use four-digit years wherever possible to avoid any ambiguity.) We'll take a look at some of the other informats and formats available later in this lesson. Now, we'll go take a look at some of the available functions that work specifically with SAS dates.

Example 22.6

The following SAS program creates a temporary SAS data set called createdates that contains six date variables. The variables current1 and current2 are assigned the current date using the date( )and today( ) functions. The variable current3 is assigned the 95th day of the 2008 year using the datejul( ) function. The variables current4 and current5 are assigned the date April 4th, 2008 using the mdy( ) function. And, the variable current6 is assigned the date April 1st, 2008 using the yyq( ) function.

DATA createdates;
    current1= date();
    current2 = today();
    current3 = datejul(2008095);
    mon = 4; day = 4; year = 2008;
    current4 = mdy(mon, day, year);
    current5 = current4;
    current6 = yyq(2008, 2);
    format current1 current2 current3 current5 current6 date9.;
RUN;

PROC PRINT data=createdates;
    title 'The createdates data set';
    var current1 current2 current3 current4 current5 current6;
RUN;

Output

Example 22.7

The following SAS program uses the day( ), month( ), and year( ) functions to extract the month, day, and year from the wt_date variable:

DATA takeapart;
    input subj 1-4 l_name $ 18-23 weight 30-32
    	+1 wt_date mmddyy8. @43 b_date mmddyy8.;
    wt_mo = month(wt_date);
    wt_day = day(wt_date);
    wt_yr = year(wt_date);
    format wt_date b_date date9.;
	DATALINES;
1024 Alice       Smith  1 65 125 12/1/05  01/01/60
1167 Maryann     White  1 68 140 12/01/05 01/01/59
1168 Thomas      Jones  2    190 12/2/05  06/15/60
1201 Benedictine Arnold 2 68 190 11/30/05 12/31/60
1302 Felicia     Ho     1 63 115 1/1/06   06/15/58
;
 
RUN;
 
PROC PRINT data=takeapart;
    title 'The dissected weight dates';
	var wt_date wt_mo wt_day wt_yr;
RUN;

Output

Example 22.8

The following SAS program contains four assignment statements that "massage" the wt_date variable. The variable wt_jul1 is assigned the SAS Julian date in yyddd format. The variable wt_jul2 is assigned the SAS Julian date in yyyyddd format. The variable wt_qtr is assigned the quarter in which the wt_date occurs, and the variable wt_day is assigned the weekday on which the wt_date occurs:

DATA massaged;
	input subj 1-4 l_name $ 18-23 weight 30-32
    	+1 wt_date mmddyy8. @43 b_date mmddyy8.;
    wt_jul1 = juldate(wt_date);
    wt_jul2 = juldate7(wt_date);
    wt_qtr = qtr(wt_date);
    wt_day = weekday(wt_date);
    format wt_date b_date date9.;
    DATALINES;
1024 Alice       Smith  1 65 125 12/1/05  01/01/60
1167 Maryann     White  1 68 140 12/01/05 01/01/59
1168 Thomas      Jones  2    190 12/2/05  06/15/60
1201 Benedictine Arnold 2 68 190 11/30/05 12/31/60
1302 Felicia     Ho     1 63 115 1/1/06   06/15/58
;

RUN;

PROC PRINT data = massaged;
	title 'The massaged data set';
    var wt_date wt_jul1 wt_jul2 wt_qtr wt_day;
RUN;

Output

First, review the program to make sure that you understand how to use each of the four functions. Then, launch and run the SAS program, and review the output to convince yourself that the program does as claimed.

Example 22.9

The following SAS program uses the yrdif( ) function to calculate the difference between the subject's birth date (b_date) and first weight date (wt_date1) in order to determine the subject's age. And, the datdif( ) function is used to calculate days, the difference between the subject's first (wt_date1) and second (wt_date2) weight dates:

DATA diet;
	input subj 1-4 l_name $ 18-23 weight 30-32
        +1 wt_date1 mmddyy8. @43 wt_date2 mmddyy8. @52 
    	b_date mmddyy8.;
    age  = yrdif(b_date, wt_date1, 'act/act');
    days = datdif(wt_date1, wt_date2, 'act/act');
    format wt_date1 wt_date2 b_date date9.  age 4.1;
	DATALINES;
1024 Alice       Smith  1 65 125 12/1/05  03/04/06 01/01/60
1167 Maryann     White  1 68 140 12/01/05 03/07/06 01/01/59
1168 Thomas      Jones  2    190 12/2/05  3/30/06  06/15/60
1201 Benedictine Arnold 2 68 190 11/30/05 2/27/06  12/31/60
1302 Felicia     Ho     1 63 115 1/1/06   4/1/06   06/15/58
	;
RUN;
 
PROC PRINT data=diet;
    TITLE "The calculation of subject's age";
	var subj b_date wt_date1 age;
RUN;
 
PROC PRINT data=diet;
    TITLE 'The calculation of days between weighings';
	var subj wt_date1 wt_date2 days;
RUN;

Output

Review the assignment statement that is used to calculate the values for the variable age. The first and second arguments of the yrdif( ) function tell SAS, respectively, the start and end date of the desired interval. Here, the start date is b_date and the end date is wt_date1. The third argument of the yrdif( ) function, which must be enclosed in single quotes, tells SAS how to calculate the difference. Here, 'act/act' tells SAS to calculate the difference using the actual number of years between the two dates. The four possible methods in calculating the number of years between two dates using the yrdif( ) function are:

• 'act/act' uses the actual number of days and years between two dates
• '30/360' specifies a 30-day month and a 360-day year
• 'act/360' uses the actual number of days between dates in calculating the number of years (calculated by the number of days divided by 360)
• 'act/365' uses the actual number of days between dates in calculating the number of years (calculated by the number of days divided by 365)

The 'act/act' method is the method that most people would consider to be the most accurate. The other methods are methods that are sometimes used by accountants.

Now, review the assignment statement that is used to calculate the values for the variable days. The first and second arguments of the datdif( ) function tell SAS, respectively, the start and end date of the desired interval. Here, the start date is wt_date1 and the end date is wt_date2. The third argument of the datdif( ) function, which must be enclosed in single quotes, tells SAS how to calculate the difference. Here, 'act/act' tells SAS to calculate the difference using the actual number of days between the two dates. The two possible methods for calculating the number of days between two dates using the datdif( ) function are:

• 'act/act' uses the actual number of days and years between two dates
• '30/360' specifies a 30-day month and a 360-day year

Again, the 'act/act' method is the method that most people would consider to be the most accurate. The other method is a method that is sometimes used by accountants.

When you are satisfied that you understand the two functions, launch and run the SAS program. Review the output to convince yourself that age and days are indeed calculated as described.

Example 22.10

Recall that the intck( ) function returns the number of time intervals, such as the number of days or years, that occur between two dates. The following SAS program is identical to the previous program, except here the subjects' ages at their first weigh-in are determined using both the yrdif( ) and intck( ) functions to get age_yrdif and age_intchk, respectively. Similarly, the number of days between the subjects' two weigh-ins is determined using both the datdif( ) and intck( ) functions to get days_datdif and days_intchk, respectively:

DATA diet;
	input subj 1-4 l_name $ 18-23 weight 30-32
    	+1 wt_date1 mmddyy8. @43 wt_date2 mmddyy8. @52 
        b_date mmddyy8.;
    age_yrdif  = yrdif(b_date, wt_date1, 'act/act');
    age_intck = intck('year', b_date, wt_date1);
    days_datdif = datdif(wt_date1, wt_date2, 'act/act');
    days_intck = intck('day', wt_date1, wt_date2);
    format wt_date1 wt_date2 b_date date9.  age 4.1;
	DATALINES;
1024 Alice       Smith  1 65 125 12/1/05  03/04/06 01/01/60
1167 Maryann     White  1 68 140 12/01/05 03/07/06 01/01/59
1168 Thomas      Jones  2    190 12/2/05  3/30/06  06/15/60
1201 Benedictine Arnold 2 68 190 11/30/05 2/27/06  12/31/60
1302 Felicia     Ho     1 63 115 1/1/06   4/1/06   06/15/58
  ;
RUN;

PROC PRINT data=diet;
	TITLE "The calculation of subject's age";
    var subj b_date wt_date1 age_yrdif age_intck;
RUN;

PROC PRINT data=diet;
	TITLE 'The calculation of days between weighings';
    var subj wt_date1 wt_date2 days_datdif days_intck;
RUN;

Output

Review the assignment statement that is used to calculate the values for the variable age_intck. The first argument of the intck( ) function, which must appear in single quotes, tells SAS what time interval you are interested in counting. Although there are other intervals available, the most commonly used intervals include 'day', 'weekday', 'week', 'month', 'qtr', and 'year'. The second and third arguments of the intck( ) function tell SAS, respectively, the start and end date of the desired interval. Here, the start date is b_date, the end date is wt_date1, and the time interval is 'year'.

Now, review the assignment statement that is used to calculate the values for the variable days_intck. To calculate days, the start date is wt_date1, the end date is wt_date2, and the time interval is 'day'.

Theoretically, we should expect the yrdif( ) and intck( ) functions to get the same answers for age, and the datdif( ) and intck( ) functions to get the same answers for days. Launch and run   the SAS program, and review the resulting output. Same answers or not? Hmmm ... you should see that the values for days_datdif and days_intck are the same, while the (rounded) values for age_yrdif and age_intck differ.

Why is that the case? It has to do with the fact that the intck( ) function counts intervals from fixed interval beginnings, not in multiples of an interval unit from the startdate value. Partial intervals are not counted. For example, 'week' intervals are counted by Sundays rather than seven-day multiples from the startdate value. 'Month' intervals are counted by the first day of each month, and 'year' intervals are counted from January 1st, not in 365-day multiples from the startdate value.

The next two examples are intended to help you understand how the intck( ) function counts intervals.

Example 22.11

The following SAS program uses the intck( ) function and SAS date constants to determine the number of days, weeks, months, and years between December 31, 2006, and January 1, 2007. It also calculates the number of years (years2) between January 1, 2007 and December 31, 2007, and the number of years (years3) between January 1, 2007 and January 1, 2008:

DATA timeintervals1;
     days = intck('day', '31dec2006'd,'01jan2007'd);
     weeks = intck('week', '31dec2006'd,'01jan2007'd);
     months = intck('month', '31dec2006'd,'01jan2007'd);
     years = intck('year', '31dec2006'd,'01jan2007'd);
     years2 = intck('year', '01jan2007'd, '31dec2007'd);
     years3 = intck('year', '01jan2007'd, '01jan2008'd);
RUN;

PROC PRINT data = timeintervals1;
	TITLE 'Time intervals as calculated by intck function';
RUN;

Output

First, review the program to make sure that you understand what it is doing. Then, launch and run   the SAS program, and review the output. Are you surprised by any of the results? Let me venture to suggest that you find the results for days, weeks, and years3 to make sense, and the results for months, years, and years2 to be a little odd. Let's focus on the three odd results. In spite of only one day passing between 12/31/2006 and 01/01/2007, SAS assigns the variable months the value 1 because, between 12/31/2006 and 01/01/2007, exactly one first day of the month is crossed (which happens to be January 1st). Similarly, in spite of only one day passing between 12/31/2006 and 01/01/2007, SAS assigns the variable years the value 1 because, between 12/31/2006 and 01/01/2007, exactly one January 1st is crossed. And, in spite of 364 days passing between 01/01/2007 and 12/31/2007, SAS assigns the variable years2 the value 0 because no January 1st is crossed. Now, even though the results for days, weeks, and years3 might make intuitive sense to you, you should still make sure you understand why SAS assigns the values it does here based on how the intck( ) function works.

Example 22.12

In an attempt to explore the intck( ) function further, the following SAS program uses the intck( ) function and SAS date constants to determine the number of days, weeks, weekdays, months, qtrs, and years between March 15, 2007 and March 15, 2008:

DATA timeintervals2;
        days = intck('day', '15mar2007'd,'15mar2008'd);
        weeks = intck('week', '15mar2007'd,'15mar2008'd);
        weekdays = intck('weekday', '15mar2007'd,'15mar2008'd);
        months = intck('month', '15mar2007'd,'15mar2008'd);
        qtrs = intck('qtr', '15mar2007'd,'15mar2008'd);
        years = intck('year', '15mar2007'd,'15mar2008'd);
RUN;
        
PROC PRINT data = timeintervals2;
       TITLE 'Time intervals as calculated by intck function';
RUN;

Output

The main purpose of this program is to illustrate some of the intervals most commonly used in the intck( ) function. First, review the program to make sure that you understand what it is doing. Then, launch and run the SAS program, and review the output. Are you surprised by any of the results? In each case, I think you'll find the results to make intuitive sense.

Example 22.13

Now, suppose that each subject appearing in the diet data set needs to be weighed again in three months. The following SAS program uses the subject's previous weight date (wt_date) and various versions of the intnx( ) function to determine various versions of each subject's next weight date:

DATA diet;
    input subj 1-4 l_name $ 18-23 weight 30-32
		+1 wt_date mmddyy8. @43 b_date mmddyy8.;
    nxdate_b1 = intnx('month', wt_date, 3);
    nxdate_b2 =  intnx('month', wt_date, 3, 'beginning');
    nxdate_m = intnx('month', wt_date, 3, 'middle');
    nxdate_e = intnx('month', wt_date, 3, 'end');
    nxdate_s = intnx('month', wt_date, 3, 'sameday');
    format wt_date b_date nxdate_b1 nxdate_b2 
     	nxdate_m nxdate_e nxdate_s date9.;
	DATALINES;
1024 Alice       Smith  1 65 125 12/1/05  01/01/60
1167 Maryann     White  1 68 140 12/01/05 01/01/59
1168 Thomas      Jones  2    190 12/2/05  06/15/60
1201 Benedictine Arnold 2 68 190 11/30/05 12/31/60
1302 Felicia     Ho     1 63 115 1/1/06   06/15/58
;
RUN;

PROC PRINT data=diet;
	TITLE 'The data set containing next weight dates';
    VAR subj wt_date nxdate_b1 nxdate_b2 
    	nxdate_m nxdate_e nxdate_s;
RUN;

Output

Let's review the five assignment statements that calculate five versions of the subjects' next weight dates (nxdate_b1, nxdate_b2, nxdate_m, nxdate_e, and nxdate_s). As you can see, SAS is told to use the 'month' interval in each of the calculations. Again, although there are other intervals available, the most commonly used intervals include 'day', 'weekday', 'week', 'month', 'qtr', and 'year'. SAS is also told to use wt_date as the startdate in each of the calculations. And in each case, SAS is told to advance the wt_date by 3 months. Okay, so the only thing that differs between the five calculations are the last (optional) arguments ('beginning', 'middle', 'end', and 'sameday'). These so-called alignment arguments tell SAS to return either the beginning, middle, or end day of the resulting month. If an alignment is not specified, the beginning day is returned by default. If the 'sameday' alignment is specified, SAS of course returns the same number day but shifted by the number of specified intervals.

Let's launch and run the SAS program, and review the output. The dates should be as described. The contents of nxdate_b1 is the same as nxdate_b2, since the beginning day is returned by default. The variable nxdate_m contains the middle day of the resulting month, and nxdate_e contains the end day of the resulting month. And, for four of the subjects, SAS returns the same number day but 3 months in the future. For subject #1201, you would expect SAS to return February 30th, because it is exactly 3 months from November 30th. This illustrates how the intnx( ) function automatically adjusts the date if the resulting date doesn't exist.

Whewww! That does it! Everything you wanted to know about SAS date functions and more. Let's move on and touch a little bit more on reading and displaying dates in SAS.

Example 22.19

The following SAS program reads five observations into a SAS data set called diet. One of the variables — weight time (wt_time) — is in hh:mm:ss format, and therefore SAS is told to read the dates using the time8. informat:

DATA diet;
input subj 1-4 l_name $ 18-23 weight 30-32
	+1 wt_date mmddyy8. @43 b_date mmddyy8.
    @52 wt_time time8.;
wtm_fmt1 = wt_time;
wtm_fmt2 = wt_time;
wtm_fmt3 = wt_time;
format wtm_fmt1 hhmm.
	wtm_fmt2 hour5.2
    wtm_fmt3 time8.;
DATALINES;
1024 Alice       Smith  1 65 125 12/1/05  01/01/60 00:01:00
1167 Maryann     White  1 68 140 12/01/05 01/01/59 00:15:00
1168 Thomas      Jones  2    190 12/2/05  06/15/60 12:00:00
1201 Benedictine Arnold 2 68 190 11/30/05 12/31/60 00:00:00
1302 Felicia     Ho     1 63 115 1/1/06   06/15/58 23:59:59
;
RUN;
    
PROC PRINT data=diet;
title 'The diet data set with formatted weight times';
var subj wt_time wtm_fmt1 wtm_fmt2 wtm_fmt3;
RUN;

Output

First, review the program so that you understand what it is doing. Specifically, pay attention to the time8. informat used to read in the wt_time variable. Also, note that three new weight time variables — wtm_fmt1, wtm_fmt2, wtm_fmt3 — are assigned to equal the values of the wt_time variable. The three new variables are each formatted differently, however. The FORMAT statement tells SAS to format wtm_fmt1 as hhmm., wtm_fmt2 as hour5.2, and wtm_fmt3 as time8.

Now, launch and run   the SAS program, and review the resulting output to familiarize yourself with the contents of the diet data set. Note, in particular, the numeric values that are stored for the unformatted wt_time variable. As expected, the 00:01:00 time is stored as a 60, the 00:00:00 time is stored as a 0, and the 00:15:00 time is stored as a 900. Then, note the formatted versions of the weight time variables. As you can see, the hhmm. format displays the time on a 24-hour clock. The hour5.2 format displays the time as hours and decimal fractions of hours. And, the time8. format displays the time as hours, minutes, and seconds in the form hh:mm:ss.

Example 22.20

The following SAS program illustrates the use of the five time functions mentioned above. Specifically, the variable curtime is assigned the current time using the time( ) function. Then, the hour( ), minute( ), and second( ) functions are used to extract the hours, minutes, and seconds from the wt_time variable. Finally, the hms( ) function is used to put the hours, minutes, and seconds back together again to create a new variable called wt_time2 that equals the old wt_time variable:

DATA diet;
input subj 1-4 l_name $ 18-23 weight 30-32
     +1 wt_date mmddyy8. @43 b_date mmddyy8.
     @52 wt_time time8.;
curtime = time();
wt_hr = hour(wt_time);
wt_min = minute(wt_time);
wt_sec = second(wt_time);
wt_time2 = hms(wt_hr, wt_min, wt_sec);
format curtime wt_time wt_time2 time8.;
DATALINES;
1024 Alice       Smith  1 65 125 12/1/05  01/01/60 00:01:00
1167 Maryann     White  1 68 140 12/01/05 01/01/59 00:15:00
1168 Thomas      Jones  2    190 12/2/05  06/15/60 12:00:00
1201 Benedictine Arnold 2 68 190 11/30/05 12/31/60 00:00:00
1302 Felicia     Ho     1 63 115 1/1/06   06/15/58 23:59:59
;
RUN;
PROC PRINT data=diet;
    title 'The diet data set with five new variables';
    var subj curtime wt_time wt_hr wt_min wt_sec wt_time2;
RUN;

Output

First, review the program to make sure that you understand how to use each of the five functions. Then, launch and run   the SAS program, and review the output to convince yourself that the program does as claimed.

Example 22.21

The following SAS program illustrates how to compare the values of a time variable, not to the values of some other time variable, but rather to a time constant. Specifically, the WHERE= option on the DATA statement tells SAS to output to the diet data set only those individuals whose wt_time is between midnight and noon, inclusive:

DATA diet (where = ((wt_time ge '00:00:00't) 
    and (wt_time le '12:00:00't)));;
    input subj 1-4 l_name $ 18-23 weight 30-32
        +1 wt_date mmddyy8. @43 b_date mmddyy8.
    	@52 wt_time time8.;
    time_int = abs((wt_time - '05:00:00't)/3600);
	format wt_time time8. time_int 4.1;
DATALINES;
1024 Alice       Smith  1 65 125 12/1/05  01/01/60 00:01:00
1167 Maryann     White  1 68 140 12/01/05 01/01/59 00:15:00
1168 Thomas      Jones  2    190 12/2/05  06/15/60 12:00:00
1201 Benedictine Arnold 2 68 190 11/30/05 12/31/60 00:00:00
1302 Felicia     Ho     1 63 115 1/1/06   06/15/58 23:59:59
; 
RUN;
 
PROC PRINT data=diet;
    title 'The subsetted diet data set';
	var subj l_name wt_time time_int;
RUN;

Output

First, review the program to make sure you understand what it is doing. Note, for example, the form of the SAS time constants:

        '00:00:00't

and

        '12:00:00't

used in the WHERE= option. In general, a SAS time constant takes the form 'hh:mm:ss't where hh is the hour in 24-hour time, mm is the minutes, and ss (optional) are the seconds. The letter t that follows the time in single quotes tells SAS to treat the time string like a constant. Note that regardless of how you have informatted or formatted your SAS times, the SAS time constant always takes the above form.

This program also illustrates how you can use SAS time variables easily in calculations. The variable time_int is assigned the absolute difference in time, in hours, between each individual's weight time and their expected weight time, say for example, 5 a.m.

Now, launch and run   the SAS program. Then, review the resulting output to convince yourself that only those individuals whose weight time is between midnight and noon are included in the output diet data set.

Well, I think that's enough for now about processing time values in SAS. As you can see, times are treated just as dates are in SAS. Once you understand one, you understand the other. Now, let's practice what we've learned in this lesson!