You might recall that the SAS data set called penngolf contains information, such as the total yardage and par, of eleven golf courses in Pennsylvania. The following program opens the HTML destination so that a subset of the penngolf data set can be printed in HTML format as well as the default Listing format:

OPTIONS PS = 58 LS = 72 NODATE NONUMBER;
LIBNAME stat481 'C:\yourdrivename\Stat481WC\12ods\sasndata';
 
ODS HTML file = 'C:\yourdrivename\Stat481WC\12ods\output\golf.html';
 
PROC PRINT data = stat481.penngolf NOOBS;
   title 'Some of the penngolf data set variables';
   ID name;
   var year type par yards;
RUN;
 
ODS HTML CLOSE;

Output

This code illustrates the standard ODS practice mentioned earlier... open your destinations at the top of your program, and close them at the bottom. Here, the first ODS statement tells SAS to open the HTML destination and to save the HTML output generated by the PRINT procedure that follows the specified file name. The second ODS statement tells SAS to close the HTML destination so that we can access the created HTML file.

Download and save the penngolf (click to save!) data set to a convenient location on your computer. Then, launch the SAS code, and edit the LIBNAME statement so that it reflects the location in which you saved the data set. Also, edit the first ODS statement's FILE= option so that it reflects the location and name of the file where you want the resulting HTML output to be sent. (Make sure that you give your filename the standard .html extension.) Finally, run   the SAS program. In doing so, you should note that SAS generates two pieces of output. The default listing output is displayed, as always, in the output window:

and the specifically requested HTML output:

is displayed in the Results Viewer. If the HTML output doesn't pop up on its own, you can see it by clicking on the Results Viewer button:

along the bottom of your SAS window.

The following program uses the penngolf data set to simultaneously create HTML output from the PRINT and REPORT procedures:

ODS LISTING CLOSE;
ODS HTML body = 'C:\yourdrivename\Stat481WC\12ods\output\golf2.html';
 
PROC PRINT data = stat481.penngolf NOOBS;
    title 'Some Par 72 Pennsylvania Golf Courses';
    ID name;
    var year type yards;
    where par = 72;
RUN;
 
PROC REPORT data = stat481.penngolf NOWINDOWS HEADLINE HEADSKIP;
    title 'Average Size of Some PA Courses';
    column type par yards;
    define type /group;
    define yards / analysis mean format = 6.1 width = 10;
    define par / analysis mean format = 4.1 width = 10;
RUN;
 
ODS HTML CLOSE;
ODS LISTING;

Before launching and running the program, let's take a quick look at the code to make sure we know what it's doing:

• The first ODS statement again tells SAS to close the Listing destination.
• The second ODS statement tells SAS to open the HTML destination and to save the HTML output generated by the code to the specified file name. Note that rather than using the ODS HTML statement's FILE= option, we used the BODY= option to tell SAS where to save the HTML output. The two options are interchangeable. That is, the BODY= option is an alias for the FILE= option.
• Then, we use the PRINT procedure to tell SAS to print some information about the par 72 golf courses.
• Then, we use the REPORT procedure to tell SAS to calculate the average yardage and average par for each of the four types of golf courses.
• The third ODS statement tells SAS to close the HTML destination so that we can access the created HTML file.
• And, the last ODS statement tells SAS to re-open the Listing destination.

Now, go ahead and launch the SAS program. Again, you'll have to edit the first ODS HTML statement to reflect where you would like your HTML file stored. Then, run   the SAS program, and review the output as it appears in the SAS Results Viewer. You should first see the output from the PRINT procedure:

Some Par7 2 Pennsylvania Golf Courses

and then the output from the REPORT procedure:

Average Size of Some PA Courses

You should also note that SAS saves the generated HTML output in the file specified in the first ODS HTML statement. To see the file, go to the folder in which you told SAS to store the HTML file. Here's what my folder looks like after running the program:

When we run the code in Example 24.2, SAS creates the golf.html file. And, when we run the above code from Example 24.3, SAS creates the golf2.html file. For some reason, I have trouble opening either file with Mozilla Firefox, but am able to do so with Internet Explorer. To do so, right-click on the golf2.html file (or whatever you've called the file), and select Open With... Internet Explorer. You should see the same output that SAS displays in the SAS Results Viewer. It is this physical golf2.html file though that you could easily post to a public website or e-mail to someone else.

When you have a program that creates many pages of output, you might find it useful for SAS to create a table of contents for the output. The following program is identical to the previous program, except the first ODS HTML statement has been modified to tell SAS to create a table of contents for the output that SAS generates:

ODS LISTING CLOSE;
ODS HTML body='C:\yourdrivename\Stat481WC\12ods\output\golf3.html'
            contents = 'C:\yourdrivename\Stat481WC\12ods\output\golf3toc.html'
            frame = 'C:\yourdrivename\Stat481WC\12ods\output\golf3frame.html';
 
PROC PRINT data = stat481.penngolf NOOBS;
    title 'Some Par 72 Pennsylvania Golf Courses';
    ID name;
    var year type yards;
    where par = 72;
RUN;
 
PROC REPORT data = stat481.penngolf NOWINDOWS HEADLINE HEADSKIP;
    title 'Average Size of Some PA Courses';
    column type par yards;
    define type /group;
    define yards / analysis mean format = 6.1 width = 10;
    define par / analysis mean format = 4.1 width = 10;
RUN;
 
ODS HTML CLOSE;
ODS LISTING;

Since the code is almost identical to the previous program, the only code that needs explanation this time around is the first ODS HTML statement. As before, the BODY= option tells SAS where we want to store the HTML output generated from the subsequent PRINT and REPORT procedures. Not surprisingly, the CONTENTS= option tells SAS where we want to store the table of contents. The FRAME= option gives SAS a place to store the HTML page containing the integrated table of contents and body file. Note that the FRAME= option and the CONTENTS= option go together. That is, if you include the FRAME= option in your ODS HTML statement, you must also include the CONTENTS= option.

Okay, go ahead and launch the SAS program, and edit the first ODS HTML statement to reflect where you would like your HTML files stored. Then, run   the SAS program, and review the output as it appears in the SAS Results Viewer. Look at this! The output looks no different than the output from the previous example. The only thing you should see in the SAS Results Viewer is the body file golf3.html. To see the results along with the table of contents and table of pages, you have to open the frame file golf3frame.html (or whatever you call the frame file). To do so, go to the folder in which you told SAS to store the HTML files. Here's what my folder looks like now after running the program:

If you click on the golf3.html file (or whatever you called the body file), and select Open With... Internet Explorer, you should again see the results of the PRINT and REPORT procedures. If you right-click on the golf3toc.html file (or whatever you called the table of contents file) and select Open With... Internet Explorer, you should see the table of contents with links to each procedure output in the body file. It's the frame file that you should find the most useful in this situation. If you right-click on the golf3frame.html file (or whatever you called the frame file) and select Open With... Internet Explorer, you should see the table of contents and the body file integrated into one page. If you click on the links in the table of contents, you can see how SAS moves you to the relevant output.

The following program tells SAS to print a subset of the penngolf data set and when doing so to send the output to an RTF destination:

ODS LISTING CLOSE;
        ODS RTF file = 'C:\Simon\Stat481WC\sp09\12ods\output\golf5.rtf'
                BODYTITLE;
        
        PROC PRINT data = stat481.penngolf NOOBS;
            title 'Some Par 72 Pennsylvania Golf Courses';
            ID name;
            var year type yards;
            where par = 72;
        RUN;
        
        ODS RTF CLOSE;
        ODS LISTING

As you can see, to tell SAS to send output to the RTF destination, we simply use the RTF keyword in an ODS statement. By default, titles and footnotes are put into Word headers and footers. The BODYTITLE option in the ODS RTF statement tells SAS to instead put titles and footnotes in the main part of the RTF document. Note that the second-to-last ODS statement tells SAS to close the RTF destination, while the last ODS statement tells SAS again to re-open the Listing destination.

Launch the SAS program. Then, edit the ODS RTF statement to reflect where you would like your RTF file stored. Then, run   the SAS program. When you do so, a pop-up window that looks something like this should appear:

If you select Open, you'll see the contents of the golf5.rtf file (or whatever you called it) in the SAS Results Viewer. You can then easily copy the contents of the Results Viewer into a Word document. Alternatively, you can go to the folder in which you told SAS to store your RTF file:

and double-click on the file to open it in Word.

The following program does exactly the same thing as the previous program, except the output here is sent to a PDF file:

            ODS LISTING CLOSE;
        ODS PDF file = 'C:\Simon\Stat481WC\sp09\12ods\output\golf6.pdf';
        
        PROC PRINT data = stat481.penngolf NOOBS;
            title 'Some Par 72 Pennsylvania Golf Courses';
            ID name;
            var year type yards;
            where par = 72;
        RUN;
        
        ODS PDF CLOSE;
        ODS LISTING;

Pretty straightforward... as you can see, to tell SAS to send output to the PDF destination, we simply use the PDF keyword in an ODS statement. Note again that the second-to-last ODS statement tells SAS to close the PDF destination, while the last ODS statement tells SAS again to re-open the Listing destination.

Launch the SAS program. Then, edit the ODS PDF statement to reflect where you would like your PDF file stored. Then, run   the SAS program. Again, there are a couple of things you can do to view the resulting PDF file. First, you can review the PDF file as it appears in the SAS Results Viewer. Alternatively, you can go to the folder in which you told SAS to store your PDF file:

and double-click on the file to open it.

The following program uses ODS TRACE statements to capture information about the output objects created by the MEANS procedure on a data set called golfbypar, which is just a sorted version of the penngolf data set:

PROC SORT data = stat481.penngolf out = golfbypar;
    by par;
RUN;
 
ODS TRACE ON;
PROC MEANS data = golfbypar;
    by par;
    title 'Pennsylvania Golf Courses by Par';
RUN;
ODS TRACE OFF;

Output

The SORT procedure, of course, just sorts the permanent data set stat481.penngolf by par and stores the sorted result in a temporary data set called golfbypar. Then, the ODS TRACE ON statement tells SAS to start capturing information about any output objects that are created. The MEANS procedure tells SAS to summarize the golfbypar data set for each level of par, that is when par equals 70, 71, and 72. Finally, the ODS TRACE OFF statement tells SAS to stop capturing information about any output objects that are created.

Launch and run   the SAS program. You can go ahead and review the output from the MEANS procedure, but what we're really interested in here is the information SAS displays about the output objects in the log window:

   ODS TRACE ON;
   PROC MEANS data = golfbypar;
       by par;
       title 'Pennsylvania Golf Courses by Par';
   RUN;
NOTE: Writing HTML Body file: sashtml.htm
Output Added:
-------------
Name:       Summary
Label:      Summary statistics
Template:   base.summary
Path:       Means.ByGroup1.Summary
-------------
NOTE: The above message was for the following BY group:
      Par=70
Output Added:
-------------
Name:       Summary
Label:      Summary statistics
Template:   base.summary
Path:       Means.ByGroup2.Summary
-------------
NOTE: The above message was for the following BY group:
      Par=71
Output Added:
-------------
Name:       Summary
Label:      Summary statistics
Template:   base.summary
Path:       Means.ByGroup3.Summary
-------------
NOTE: The above message was for the following BY group:
      Par=72
NOTE: There were 11 observations read from the data set WORK.GOLFBYPAR.
NOTE: PROCEDURE MEANS used (Total process time):
      real time           0.70 seconds
      cpu time            0.39 seconds
   ODS TRACE OFF;

As the log suggests, the MEANS procedure creates one output object for each BY group (par = 70, par = 71, and par = 72). The three output objects share the same name, label, and template, but different paths. The path for the par = 70 output object, for example, is called Means.ByGroup1.Summary and the path for the par = 71 output object is called Means.ByGroup2.Summary. Once we know the names of the output objects, we can use an ODS SELECT statement to tell SAS the specific output objects that we want to be displayed. To select specific output objects, simply place an ODS SELECT statement within the relevant procedure. By default, the ODS SELECT statement lasts only for the procedure in which it is contained.

The following program uses an ODS SELECT statement and what we learned from tracing our MEANS procedure to print just the portion of the output that pertains to the par 70 golf courses:

PROC MEANS data = golfbypar;
    by par;
    title 'Par 70 Golf Courses';
    ODS SELECT Means.ByGroup1.Summary;
RUN;

Output

Launch and run   the SAS program, and review the output to convince yourself that SAS displays only the portion of the MEANS procedure that pertains to the par 70 golf courses.

The following program uses the ODS HTML statement's STYLE= option to tell SAS to use the meadow style when displaying the HTML output created by printing a subset of the stat481.penngolf data set:

ODS HTML file = 'C:\yourdrivename\Stat481WC\12ods\output\golf9.html'
        style = meadow;
 
PROC PRINT data = stat481.penngolf NOOBS;
title 'Some of the penngolf data set variables';
ID name;
var year type par yards;
RUN;
 
ODS HTML CLOSE;

Output

As you can see, telling SAS what style to use is as simple as adding the STYLE= option to the ODS HTML statement. Launch and run   the SAS program, and review the output to see the appearance of the HTML output when created using the meadow style template.

Of course you are asking yourself "how would I know that meadow is one of the available predefined styles?" Fortunately, the answer is simple enough. The following TEMPLATE procedure produces a list of the predefined style templates that are available on your system:

PROC TEMPLATE;
    LIST STYLES;
RUN;

Output

Launch and run   the SAS code, and review the output to see the list of predefined styles that are shipped with SAS. You might want to try some of the styles out yourself. While I do find some of the styles rather nice, I personally find some of them rather hideous (and therefore useless to me).

The following program uses an ODS OUTPUT statement to create a temporary SAS data set called summout from the Summary output object created by the MEANS procedure, and then prints the resulting summout data set:

PROC MEANS data = golfbypar;
        by par;
        var yards;
        title 'Pennsylvania Golf Courses by Par';
        ODS OUTPUT Summary = summout;
    RUN;
    PROC PRINT data = summout NOOBS;
        title 'The summout data set';
    RUN;

Output

Now, something that might not be obvious from this code is that the name of the output object, Summary, was determined from first tracing the MEANS procedure. If you refer back to the information SAS displayed in the log for Example 24.7, you can see that, since we want to capture all of the output from the MEANS procedure, the desired output object is called Summary. The ODS OUTPUT statement tells SAS that we want to save the data contained in the Summary output object in a data set called summout. Of course, the PRINT procedure then tells SAS to print the summout data set. Launch and run   the SAS program, and review the output to convince yourself that the summout data set does indeed contain the data summarized by the MEANS procedure.

You do need to be careful where you put ODS statements in your program. For example, if rather than putting the ODS OUTPUT statement just before the MEAN procedure's RUN statement, we had instead put it after the MEAN procedure's RUN statement and before the PRINT procedure's PROC PRINT statement, we would not have captured the Summary data set. Instead, we would get the following Warning message:

WARNING: Output 'Summary' was not created. Make sure that the output
	Object name, label, or path is spelled corectly. Also
    	Verify that the appropriate procedute options are used to
    	produce the request output object. For example, verify that
    	the NOPRINT option is not used

You might want to move the ODS statement as described and re-run   the SAS program just to see this for yourself.