The Split-plot ANOVA is perhaps the most traditional approach, for which hand calculations are not too unreasonable. It involves modeling the data using the linear model shown below:

Model: \(Y_{ijk} = \mu + \alpha_i + \beta_{j(i)}+ \tau_k + (\alpha\tau)_{ik} + \epsilon_{ijk}\)

Using this linear model we are going to assume that the data for treatment i for dog j at time k is equal to an overall mean μ plus the treatment effect \(\alpha_i\), the effect of the dog within that treatment \(\beta_{j \left( i \right)}\), the effect of time \(τ_k\), the effect of the interaction between time and treatment \(\left(ατ \right)_{ik}\), and the error \(\varepsilon_{ijk}\).

Such that:

• \(\mu\) = overall mean
• \(\alpha_i\) = effect of treatment i
• \(\beta_{j \left( i \right)}\) = random effect of dog j receiving treatment i
• \(\tau_{k}\)= effect of time k
• \(\left( \alpha \tau \right)_{ik}\) = treatment by time interaction
• \(\varepsilon_{ijk}\) = experimental error

Assumptions:

We are going to make the following assumptions about the data:

1. The errors \(\varepsilon_{ijk}\) are independently sampled from a normal distribution with mean 0 and variance \(\sigma^2_{\epsilon}\).
2. The individual dog effects \(\beta_{j \left( i \right)}\) are also independently sampled from a normal distribution with mean 0 and variance \(\sigma^2_{\beta}\).
3. The effect of time does not depend on the dog; that is, there is no time-by-dog interaction. Generally,
4. we need to have this assumption otherwise the results would depend on which animal you were looking at - which would mean that we could not predict much for new animals.

With these assumptions, the random effect of the dog and fixed effects for treatment and time is called a mixed-effects model.

The analysis is carried out in this Analysis of Variance Table shown below:

where, 

     a: the number of treatments

     N: the total number of all experimental units

      t: number of time points

The sources of the variation include treatment; Error (a); the effect of Time; the interaction between time and treatment; and Error (b). Error (a) is the effect of subjects within treatments and Error (b) is the individual error in the model.  All these add up to the total.

Mean Square (MS) is always derived by dividing the Sum of Square term by the corresponding degrees of freedom.

To get the main effects of the treatment we compare the MS treatment to MS error (a)

We will compare these results with the results we get from the MANOVA, the next approach covered in this lesson.

This approach and these results assume a constant correlation between any two observations from the same dog. This assumption is unlikely because, typically, when you have repeated measurements over time, the data from the same subject at two different points in time are temporally correlated. In principle, observations that are collected at times that are close together are going to be more similar to one another than observations that are far apart.

This motivates an alternative approach, which is to treat this situation as a Multivariate Analysis of Variance problem instead of an Analysis of Variance problem.

When taking a multivariate approach, we collect the observations over time from the same dog, dog j receiving treatment i into a vector:

\(\mathbf{Y}_{ij} = \left(\begin{array}{c}Y_{ij1}\\ Y_{ij2} \\ \vdots\\ Y_{ijt}\end{array}\right)\)

We treat the data collected at different points in time as if it were data from different variables. Basically, we have a vector of observations for dog j receiving treatment i and each entry corresponds to data collected at a particular point in time.

The usual assumptions are made for a one-way MANOVA. In this case:

1. Dogs receiving treatment i have common mean vector \(\mu_{i}\)
2. All dogs have a common variance-covariance matrix \(\Sigma\)
3. Data from different dogs are independently sampled
4. Data are multivariate normally distributed

The Analysis

Step 1: Use a MANOVA to test for overall differences between the mean vectors of the four different observations and the treatments.

options ls=78;
title "Repeated Measures - Coronary Sinus Potassium in Dogs";


data dogs;
  infile "D:\Statistics\STAT 505\data\dog1.csv" firstobs=2 delimiter=',';
  input treat dog p1 p2 p3 p4;
  run;

proc print data=dogs;
  run;

 /* The class statement specifies treat as a categorical variable.
  * The model statement specifies p1 through p4 as the responses 
  * and treat as the factor.
  * The h= option in the manova statement is used to specify over 
  * which groups the mean response vectors are to be compared.
  * The m= option specifies the transformation (if any) to be
  * applied to the responses before the means are calculated.
  */

proc glm data=dogs;
  class treat;
  model p1 p2 p3 p4=treat;
  manova h=treat / printe;
  manova h=treat m=p1+p2+p3+p4;
  manova h=treat m=p2-p1,p3-p2,p4-p3;
  run;

If we find that there is a significant difference, then with repeated measures data we tend to focus on a couple of additional questions:

• First Question

  Is there a significant treatment by time interaction? Or, in other words, does the effect of treatment depend on the observation time? Previously in the ANOVA analysis, this question was evaluated by looking at the F-value, 2.06. This was reported as a significant result. If we find that this is a significant interaction, the next thing we need to address is, what is the nature of that interaction.

• Alternative Question

  If we do not find a significant interaction, then we can collapse the data and determine if the average sinus potassium level over time differs significantly among treatments.  Here, we are looking at the main effects of treatment.

Let's proceed...

options ls=78;
title "Profile Plot - Dog Data";

 /* After reading in the dog1 data, the variables are stacked
  * into two columns, one named 'time' for the time points and
  * one named 'k' for the quantitative response values.
  * The original p1 through p4 responses are removed.
  */

data dogs;
  infile "D:\Statistics\STAT 505\data\dog1.csv" firstobs=2 delimiter=',';
  input treat dog p1 p2 p3 p4;
  time=1;  k=p1; output;
  time=5;  k=p2; output;
  time=9;  k=p3; output;
  time=13; k=p4; output;
  drop p1 p2 p3 p4;
  run;

 /* This sorts the data by both treat and time.
  * The priority is to sort by treat first, then time
  */

proc sort data=dogs;
  by treat time;
  run;

 /* This calculates the mean response k for each level
  * of treat and time. The results are saved in a separate
  * file called 'a' with means stored as 'mean'.
  */

proc means data=dogs;
  by treat time;
  var k;
  output out=a mean=mean;

filename t1 "dog.ps";
goptions device=ps300 gsfname=t1 gsfmode=replace;

 /* The axis commands define the size of the plotting window.
  * The plot statement specifies the mean for each time and treat
  * are to be plotted but with separate lines for treat.
  * Each treat group is given a different symbol for distinction.
  * /

proc gplot;
  axis1 length=4 in;
  axis2 length=6 in;
  plot mean*time=treat / vaxis=axis1 haxis=axis2;
  symbol1 v=J f=special h=2 i=join color=black;
  symbol2 v=K f=special h=2 i=join color=black;
  symbol3 v=L f=special h=2 i=join color=black;
  symbol4 v=M f=special h=2 i=join color=black;
  run;

This program plots the treatment means against time, separately for each treatment. Here, the means for treatment 1 are given by the circles, treatment 2 squares, treatment 3 triangles, and treatment 4 stars.

The test for interaction tests the hypothesis that these line segments are parallel to one another.

To test for interaction, we define a new data vector for each observation. Here we consider the data vector for dog j receiving treatment i. This data vector is obtained by subtracting the data from time 2 minus the data from time 1, the data from time 3 minus the data from time 2, and so on...

This yields the vector of differences between successive times and is expressed as follows:

\(\mathbf{Z}_{ij} = \left(\begin{array}{c}Z_{ij1}\\ Z_{ij2} \\ \vdots \\ Z_{ij, t-1}\end{array}\right) = \left(\begin{array}{c}Y_{ij2}-Y_{ij1}\\ Y_{ij3}-Y_{ij2} \\ \vdots \\Y_{ijt}-Y_{ij,t-1}\end{array}\right)\)

Because this vector is a function of the random data, it is a random vector, and so has a population mean. Thus, for treatment i, we define the population mean vector \(E(\mathbf{Z}_{ij}) = \boldsymbol{\mu}_{Z_i}\).

Then we will perform a MANOVA on these \(Z_{ij}\)'s to test the null hypothesis that

\(H_0\colon \boldsymbol{\mu}_{Z_1} = \boldsymbol{\mu}_{Z_2} = \dots = \boldsymbol{\mu}_{Z_a} \)

options ls=78;
title "Repeated Measures - Coronary Sinus Potassium in Dogs";


data dogs;
  infile "D:\Statistics\STAT 505\data\dog1.csv" firstobs=2 delimiter=',';
  input treat dog p1 p2 p3 p4;
  run;

proc print data=dogs;
  run;

 /* The class statement specifies treat as a categorical variable.
  * The model statement specifies p1 through p4 as the responses 
  * and treat as the factor.
  * The h= option in the manova statement is used to specify over 
  * which groups the mean response vectors are to be compared.
  * The m= option specifies the transformation (if any) to be
  * applied to the responses before the means are calculated.
  */

proc glm data=dogs;
  class treat;
  model p1 p2 p3 p4=treat;
  manova h=treat / printe;
  manova h=treat m=p1+p2+p3+p4;
  manova h=treat m=p2-p1,p3-p2,p4-p3;
  run;

In the third MANOVA statement, we are testing for interaction between treatment and time. We obtain the vector Z, by setting m equal to the differences between the data at different times. i.e., p2-p1, p3-p2, and p4-p3. This will carry out the profile analysis, or equivalently, test for interactions between treatment and time.

Let's look at the output. Again, be careful when you look at the results to make sure you are in the right part of the output.

Find the table with the kind of function used in defining the vector MVAR, comprised of the elements MVAR1, MVAR2, and MVAR3.

For MVAR1 we have minus p1 plus p2, for MVAR 2 we have minus p2 plus p3, and so on...

The results are then found below this table in the SAS output:

Here we get a Wilks Lambda of 0.598 with a supporting F-value of 1.91 with 9 and 73 d.f.

This p-value is not significant if we strictly adhere to the 0.05 significance level.

There is weak evidence that the effect of treatment depends on time \( \left( \Lambda = 0.598; F = 1.91; d. f. = 9, 73; p = 0.0637 \right) \).

By reporting the p-value with our results, we allow the reader to make their own judgment regarding the significance of the test. Conservative readers might say that 0.0637 is not significant and categorically state that this is not significant, inferring that there is no evidence for an interaction. More liberal readers, however, might say that this is very close and consider this weak evidence for an interaction. When you report the results in this form, including the p-value, you allow the reader to make their own judgment.

Because the results are deemed to be not significant then the next step is to test for the main effects of the treatment.

We now define a new variable equal to the sum of the observations for each animal. To test for the main treatment effect, consider the following linear combination of the observations for each dog; that is, the sum of all the data points collected for animal j receiving treatment i.

\(Z_{ij} = Y_{ij1}+Y_{ij2}+\dots + Y_{ijt}\)

This is going to be a random variable and a scalar quantity. We could then define the mean as:

\(E(Z_{ij}) = \mu_{Z_i} \)

Consider testing the following hypothesis that all of these means are equal to one another against the alternative that at least two of them are different, or:

\(H_0\colon \mathbf{\mu}_{Z_1} =\mathbf{\mu}_{Z_2} = \dots = \mathbf{\mu}_{Z_a} \)

options ls=78;
title "Repeated Measures - Coronary Sinus Potassium in Dogs";


data dogs;
  infile "D:\Statistics\STAT 505\data\dog1.csv" firstobs=2 delimiter=',';
  input treat dog p1 p2 p3 p4;
  run;

proc print data=dogs;
  run;

 /* The class statement specifies treat as a categorical variable.
  * The model statement specifies p1 through p4 as the responses 
  * and treat as the factor.
  * The h= option in the manova statement is used to specify over 
  * which groups the mean response vectors are to be compared.
  * The m= option specifies the transformation (if any) to be
  * applied to the responses before the means are calculated.
  */

proc glm data=dogs;
  class treat;
  model p1 p2 p3 p4=treat;
  manova h=treat / printe;
  manova h=treat m=p1+p2+p3+p4;
  manova h=treat m=p2-p1,p3-p2,p4-p3;
  run;

In this lesson we learned about:

• The split-plot ANOVA for testing interactions between treatment and time, and the main effects of treatment and time;
• The use of MANOVA to test interactions between treatment and time, and the main effects of treatment and time;
• The shortcomings of the split-plot ANOVA and MANOVA procedures for analyzing repeated measures data.