# 15.8 - Analysis - Continuous Outcome

15.8 - Analysis - Continuous Outcome

The statistical analysis of normally-distributed data from a 2 × 2 crossover trial, under the assumption that the carryover effects are equal $$\left(\lambda_A = \lambda_A = \lambda\right)$$, is relatively straightforward.

Remember the statistical model we assumed for continuous data from the 2 × 2 crossover trial:

 Period 1 Period 2 Sequence AB $$\mu_A + \nu + \rho$$ $$\mu_B + \nu - \rho + \lambda_A$$ Sequence BA $$mu_B - \nu + \rho$$ $$mu_A - \nu - \rho + \lambda_B$$

For a patient in the AB sequence, the Period 1 vs. Period 2 difference has expectation $$\mu_{AB} = \mu_A - \mu_B + 2\rho - \lambda$$.

For a patient in the BA sequence, the Period 1 vs. Period 2 difference has expectation $$\mu_{BA} = \mu_B - \mu_A + 2\rho - \lambda$$.

Therefore, we construct these differences for every patient and compare the two sequences with respect to these differences using a two-sample t test or a Wilcoxon rank sumtest. Thus, we are testing:

$$H_0 \colon \mu_{AB} - \mu_{BA} = 0$$

The expression:

$$\mu_{AB} - \mu_{BA} = 2\left( \mu_A - \mu_B \right)$$

so testing $$H_0 \colon \mu_{AB} - \mu_{BA} = 0$$, is equivalent to testing:

$$H_0 \colon \mu_A - \mu_B = 0$$

To get a confidence interval for $$\mu_A - \mu_B$$ , simply multiply each difference by ½ prior to constructing the confidence interval for the difference in population means for two independent samples.

## SAS® Example

### Analysis of the data from a 2x2 crossover using SAS

This is an example of an analysis of the data from a 2 × 2 crossover trial. The example is taken from Example 3.1 from Senn's book (Senn S. Cross-over Trials in Clinical Research , Chichester, England: John Wiley & Sons, 1993). The data set consists of 13 children enrolled in a trial to investigate the effects of two bronchodilators, formoterol and salbutamol, in the treatment of asthma. The outcome variable is peak expiratory flow rate (liters per minute) and was measured eight hours after treatment. There was a one-day washout period between treatment periods.

*************************************************************************
* This is an example of an analysis of the data from a 2x2 crossover    *
* using SAS.  The example is taken from Example 3.1 of                  *
*    Senn, S.  (1993).  Cross-over Trials in Clinical Research.         *
*    Chichester, England:  John Wiley & Sons.                           *
*                                                                       *
* The data set consists of 13 children enrolled in a trial to           *
* investigate the effects of two bronchodilators in the treatment of    *
* asthma.  The outcome variable is peak expiratory flow rate (liters    *
* per minute) and was measured eight hours after treatment.  There was  *
* a one-day washout period between treatment periods.                   *
*************************************************************************;

proc format;
value trtfmt 1='Salbutamol' 2='Formoterol';
run;

data senn;
input patient sequence \$ salbutamol formoterol;
cards;
01 FS 270 310
02 SF 370 385
03 SF 310 400
04 FS 260 310
05 SF 380 410
06 FS 300 370
07 FS 390 410
09 SF 290 320
10 FS 210 250
11 FS 350 380
12 SF 260 340
13 SF  90 220
14 FS 365 330
;
run;

proc print data=senn;
title 'Formoterol vs. Salbutamol in the 2x2 Crossover Trial';
run;

*************************************************************************
* Construct the intra-subject differences (times one-half) within each  *
* sequence.  Then perform the statistical analysis.                     *
*************************************************************************;

data diff;
set senn;
if sequence='FS' then diff=0.5*(formoterol-salbutamol);
if sequence='SF' then diff=0.5*(salbutamol-formoterol);
run;

proc sort data=diff;
by sequence;
run;

proc univariate data=diff normal plot;
by sequence;
var diff;
title2 'Descriptive Statistics and Graphics for Treatment Difference';
run;

proc ttest data=diff;
class sequence;
var diff;
title2 'Parametric Analysis';
run;

proc npar1way data=diff wilcoxon;
class sequence;
var diff;
title2 'Nonparametric Analysis';
run;


The estimated treatment mean difference was 46.6 L/min in favor of formoterol $$\left(p = 0.0012\right)$$ and the 95% confidence interval for the treatment mean difference is (22.9, 70.3). The Wilcoxon rank sumtest also indicated statistical significance between the treatment groups $$\left(p = 0.0276\right)$$.

  Link ↥ Has Tooltip/Popover Toggleable Visibility