15.12 - Bioequivalence Trials
15.12 - Bioequivalence TrialsThe objective of a bioequivalence trial is to determine whether test (T) and reference (R) formulations of a pharmaceutical product are "equivalent" with respect to blood concentration × time profiles.
Bioequivalence trials are of interest in two basic situations:
- Company A demonstrates the safety and efficacy of a drug formulation, but wishes to market a more convenient formulation, ( i.e., an injection vs a time-release capsule). This situation is less common.
- Company B wishes to market a drug formulation similar to the approved formulation of Company A with an expired patent. Company B has to prove that they can deliver the same amount of active drug into the blood stream which the approved formula does.
Pharmaceutical scientists use crossover designs for such trials in order for each trial participant to yield a profile for both formulations. The blood concentration × time profile is a multivariate response and is a surrogate measure of therapeutic response. The pharmaceutical company does not need to demonstrate the safety and efficacy of the drug because that already has been established.
Are the reference and test blood concentration × time profiles similar? The test formulation could be toxic if it yields concentration levels higher than the reference formulation. On the other hand, the test formulation could be ineffective if it yields concentration levels lower than the reference formulation.
Typically, pharmaceutical scientists summarize the rate and extent of drug absorption with summary measurements of the blood concentration × time profile, such as area under the curve (AUC), maximum concentration (CMAX), etc. These summary measurements are subjected to statistical analysis (not the profiles) and inferences are drawn as to whether or not the formulations are bioequivalent.
There are numerous definitions for what is meant by bioequivalence:
- population bioequivalence - the formulations are equivalent with respect to their underlying probability distributions. You want the see that the AUC or CMAX distributions would be similar.
- average bioequivalence - the formulations are equivalent with respect to the means (medians) of their probability distributions.
- individual bioequivalence - the formulations are equivalent for a large proportion of individuals in the population. i.e., how well do the AUC's and CMAX compare across patients?
Prescribability means that a patient is ready to embark on a treatment regimen for the first time, so that either the reference or test formulations can be chosen. Switchability means that a patient, who already has established a regimen on either the reference or test formulation, can switch to the other formulation without any noticeable change in efficacy and safety.
Prescribability requires that the test and reference formulations are population bioequivalent, whereas switchability requires that the test and reference formulations have individual bioequivalence.
Currently, the USFDA only requires pharmaceutical companies to establish that the test and reference formulations are average bioequivalent. It is felt that most consumers, however, assume bioequivalence refers to individual bioequivalence, and that switching formulations does not lead to any health problems.
The hypothesis testing problem for assessing average bioequivalence is stated as:
\(H_0 : { \dfrac{\mu_T}{ \mu_R} ≤ \Psi_1 \text{ or } \dfrac{\mu_T}{ \mu_R} ≥ \Psi_2 }\) vs. \(H_1 : {\Psi_1 < \dfrac{\mu_T}{ \mu_R} < \Psi_2 }\)
where \(\mu_T\) and \(\mu_R\) represent the population means for the test and reference formulations, respectively, and \(\Psi_1\) and \(\Psi_2\) are chosen constants.
The FDA recommended values are \(\Psi_1 = 0.80\) and \(\Psi_2 = 1.25\), ( i.e., the ratios 4/5 and 5/4), for responses such as AUC and CMAX which typically follow lognormal distributions.
Thus, a logarithmic transformation typically is applied to the summary measure, the statistical analysis is performed for the crossover experiment, and then the two one-sided testing approach or corresponding confidence intervals are calculated for the purposes of investigating average bioequivalence.
SAS® Example
Assessment of average bioequivalence from a 2x2 crossover design
Test and reference formulations were studied in a bioequivalence trial that used a 2 × 2 crossover design. There were 28 healthy volunteers, (instead of patients with disease), who were randomized (14 each to the TR and RT sequences). AUC and CMAX were measured and transformed via the natural logarithm.
*************************************************************************
* This is a SAS program that illustrates the assessment of average *
* bioequivalence from a 2x2 crossover design *
*************************************************************************;
data bioequiv;
input subject sequence $ AUC_T CMAX_T AUC_R CMAX_R;
logAUC_T=log(AUC_T);
logCMAX_T=log(CMAX_T);
logAUC_R=log(AUC_R);
logCMAX_R=log(CMAX_R);
cards;
01 TR 4321.7 360.11 4415.3 278.48
02 RT 2139.5 326.19 8846.2 605.45
03 RT 8295.5 578.66 7399.1 608.67
04 TR 5974.9 412.69 3071.2 196.19
05 TR 5121.9 423.98 7513.4 681.34
06 TR 18750.4 1359.86 17096.2 1191.91
07 RT 5609.7 1046.37 4498.8 392.45
08 RT 9040.9 733.80 7847.2 571.51
09 TR 21120.1 2403.67 22603.2 1449.63
10 RT 4865.3 669.17 8127.3 738.77
11 RT 7244.6 717.01 6249.4 364.80
12 TR 5543.7 409.05 4915.3 468.31
13 RT 9748.2 907.64 12218.5 884.73
14 RT 10257.4 995.68 6021.4 557.16
15 TR 10996.2 2434.96 15284.0 2509.14
16 TR 8031.0 476.31 2495.1 265.09
17 TR 6527.5 565.66 14736.4 1070.06
18 RT 6385.5 579.72 5118.7 483.04
19 RT 4077.1 297.07 2068.3 123.90
20 TR 7088.0 1334.96 6363.2 1064.23
21 RT 10689.3 1702.07 36108.5 2552.32
22 RT 4615.1 656.33 4551.9 403.34
23 TR 3792.8 441.33 10444.7 2057.38
24 TR 9429.5 1458.82 21239.7 1899.42
25 TR 4272.4 500.45 7247.8 945.48
26 RT 9442.7 905.35 3872.8 247.49
27 RT 7373.2 688.03 5522.3 449.56
28 TR 1883.5 139.61 3299.3 213.63
;
run;
*************************************************************************
* Construct the intra-subject differences (times one-half) within each *
* sequence. Then perform the statistical analysis. *
*************************************************************************;
data diff;
set bioequiv;
if sequence='TR' then logAUC_diff=0.5*(logAUC_T-logAUC_R);
if sequence='RT' then logAUC_diff=0.5*(logAUC_R-logAUC_T);
if sequence='TR' then logCMAX_diff=0.5*(logCMAX_T-logCMAX_R);
if sequence='RT' then logCMAX_diff=0.5*(logCMAX_R-logCMAX_T);
run;
proc ttest data=diff alpha=0.10;
class sequence;
var logAUC_diff logCMAX_diff;
title2 'Parametric Analysis';
run;
The analysis yielded the following results:
AUC | CMAX | |
Est for \(\text{log}_e \dfrac{\mu_R}{\mu_T}\) | 0.0893 | -0.104 |
Est for \(\dfrac{\mu_R}{\mu_T}\) | 1.09 | 0.90 |
95% CI for \(\text{log}_e \dfrac{\mu_R}{\mu_T}\) | (-0.113, 0.294) | (-0.289, 0.080) |
95% CI for \(\dfrac{\mu_R}{\mu_T}\) | (0.89, 1.34) | (0.75, 1.08) |
Neither 90% confidence interval lies within (0.80, 1.25) specified by the USFDA, therefore bioequivalence cannot be concluded in this example and the USFDA would not allow this company to market their generic drug. Both CMAX and AUC are used because they summarize the desired equivalence.