The following program illustrates how to use a SAS data step to obtain an exact-sized random sample without replacement. Specifically, the program uses the ranuni function in a DATA step to tell SAS to randomly sample exactly 15 of the 50 observations from the permanent SAS data set mailing:

DATA sample2;
	set stat482.mailing nobs=total;
	if _N_ = 1 then n=total;
	retain k 15 n;
	random = ranuni(860244);
	propn = k/n;
	if random le propn then
		do;
			output;
			k=k-1;
		end;
	n=n-1;
	if k=0 then stop;
RUN;

PROC PRINT data=sample2 NOOBS;
	title1 'Sample2: Exact-Sized Simple Random Sample';
	title2 'without Replacement';
	var num name n k random propn;
RUN;

Output

Launch and run   the SAS program. Then, review the resulting output to convince yourself that the code did indeed select a sample of 15 observations from the mailing data set.

In summary, here's the approach used to select the sample:

• For each observation in the data set, generate a uniform random number.
• Select the first observation in the original data set for inclusion in the sample if its random number is less than or equal to the proportion of records needed (15 of 50, or 0.30).
• Modify the proportion still needed in the sample. Here, it is 14/49 if the first observation was selected for the sample; and it is 15/49 if it was not. If the random number generated for the second observation is less than or equal to this proportion, include it in the sample.
• Continue this process until you have selected exactly 15 observations.

Now, how to accomplish this approach using the SAS DATA step? Here's how we did it step-by-step:

k = the number of observations needed to complete the sample.
n = the number of observations left to read from the original data set.

• Define two variables k and n, where:
• Using the NOBS= option of the SET statement, determine the number of observations in the stat482 mailing data set and assign the value to a variable called total. In general, the NOBS= option creates and names a temporary variable whose value is the total number of observations in the data set specified in the SET statement.
• For the first observation, that is, when the automatic variable _N_ equa1s 1, set the variable n to the value of the variable total (here, 50). (Recall that automatic variables are created automatically by the DATA step, are added to the program data vector, but are not output to the data set being created. The values of automatic variables are retained from one iteration of the DATA step to the next, rather than set to missing. The automatic variable _N_ is initially set to 1. Each time the DATA step loops past the DATA statement, the variable _N_ increments by 1. The value of _N_ represents the number of times the DATA step has iterated, and often equals the number of observations in the output data set.)
• Using the RETAIN statement, initialize k to 15, the number of observations desired in the final sample.
• Use the ranuni function (starting with a seed of 860244) to generate a uniform random number between 0 and 1. Use k and n to determine the proportion of observations that still needs to be selected from the mailing data set.
• If the random number generated is less than the proportion of observations still needed, then OUTPUT the observation to the output data set. When an observation is selected, reduce the number of observations still needed in the sample by 1 (that is, k = k-1).
• At the end of each iteration of the DATA step:
  • reduce the number of observations left in the mailing data set by 1 (n = n - 1)
  • determine if the sample is complete (is k = 0?). If yes, tell SAS to STOP. In general, the STOP statement tells SAS to stop processing the current DATA step immediately and resume processing statements after the end of the current DATA step.

Note that the random = ranuni( ) and propn = k/n assignments are made here only so their values can be printed. In another situation, these values would be incorporated directly in the IF statement: if ranuni( ) le k/n then do; Additionally, k and n could be dropped from the output data set, but are kept here, so their values can be printed for educational purposes.

The following code illustrates an alternative way of using a DATA step to randomly select an exact-sized random sample without replacement. The code, while less efficient — because it requires that the data set be processed twice and sorted once — may feel more natural and intuitive to you:

DATA sample3A;
	set stat482.mailing;
	random=ranuni(860244);
RUN;

PROC SORT data=sample3A;
	by random;
RUN;

DATA sample3A;
	set sample3A;
	if _N_ le 15;
RUN;

PROC PRINT data=sample3A;
	title1 'Sample3A: Exact-Sized Simple Random Sample';
	title2 'without Replacement';
RUN;

Output

Launch and run   the SAS program. Then, review the resulting output to convince yourself that the code did indeed select a sample of 15 observations from the mailing data set.

The approach used is very similar to the approach used previously for selecting an approximate-sized sample without replacement. That is:

• For each observation in the data set, use the ranuni function to generate a uniform random number and store it in the variable called random.
• Sort the data set by the random number random.
• Select the first 15 observations from the sorted data set using the automatic variable _N_ (if _N_ le 15).

By so doing, every observation in the mailing data set has an equal likelihood of being one of the first 15 observations, and therefore an equal likelihood of being selected into the sample.

The following code illustrates yet another alternative way of randomly selecting an exact-sized random sample without replacement. Specifically, the program uses the SURVEYSELECT procedure to tell SAS to randomly sample exactly 15 of the 50 observations from the permanent SAS data set mailing:

 PROC SURVEYSELECT data = stat482.mailing
			out = sample3B
			method = SRS
			seed = 12345678
			sampsize = 15;
	title;
RUN;

PROC PRINT data = sample3B;
	title1 'Sample3B: Exact-Sized Simple Random Sample';
	title2 'without Replacement (using PROC SURVEYSELECT)';
RUN;

Output

Launch and run   the SAS program. Then, review the resulting output to convince yourself that the code did indeed select a sample of 15 observations from the mailing data set. Note that the only difference between this code and the previous SURVEYSELECT code is the sampsize = 15 statement here replaces the samprate = 0.30 statement there. You might want to change the seed (seed) and sample size (sampsize) a few times to see how it affects the sample.