data FCS;
infile datalines delimiter='09'x;
input per seq drug $ pat FCS x1 x2;
datalines;
1	1	A	1	41	0	0
1	1	A	2	46	0	0
1	2	B	1	35	0	0
1	2	B	2	42	0	0
1	3	C	1	46	0	0
1	3	C	2	52	0	0
1	4	A	1	65	0	0
1	4	A	2	69	0	0
1	5	B	1	61	0	0
1	5	B	2	66	0	0
1	6	C	1	52	0	0
1	6	C	2	37	0	0
2	1	B	1	52	1	0
2	1	B	2	54	1	0
2	2	C	1	33	0	1
2	2	C	2	36	0	1
2	3	A	1	46	-1	-1
2	3	A	2	47	-1	-1
2	4	C	1	39	1	0
2	4	C	2	42	1	0
2	5	A	1	48	0	1
2	5	A	2	50	0	1
2	6	B	1	47	-1	-1
2	6	B	2	49	-1	-1
3	1	C	1	44	0	1
3	1	C	2	48	0	1
3	2	A	1	48	-1	-1
3	2	A	2	50	-1	-1
3	3	B	1	38	1	0
3	3	B	2	41	1	0
3	4	B	1	42	-1	-1
3	4	B	2	45	-1	-1
3	5	C	1	42	1	0
3	5	C	2	46	1	0
3	6	A	1	49	0	1
3	6	A	2	52	0	1
;
run;
 
/*Obtaining fit Statistics*/
proc mixed data=FCS;
  class per seq drug pat;
  model FCS = per drug seq x1 x2/ddfm=kr;
  repeated per / subject=pat(seq) type=cs rcorr;
  ods output FitStatistics=FitCS (rename=(value=CS)) FitStatistics=FitCSp; 
  title 'Compound Symmetry'; 
run; 
 
proc mixed data=FCS;
  class per seq drug pat;
  model FCS = per drug seq x1 x2/ddfm=kr;
  repeated per / subject=pat(seq) type=AR(1) rcorr;
  ods output FitStatistics=FitAR1 (rename=(value=AR1)) FitStatistics=FitAR1p; 
  title 'Autoregressive Lag 1'; 
run; 
 
proc mixed data=FCS;
  class per seq drug pat;
  model FCS = per drug seq x1 x2/ddfm=kr;
  repeated per / subject=pat(seq) type=UN rcorr;
  ods output FitStatistics=FitUN (rename=(value=UN)) FitStatistics=FitUNp; 
 title 'Unstructured'; 
run; 
 
proc mixed data=FCS;
  class per seq drug pat;
  model FCS = per drug seq x1 x2/ddfm=kr;
  repeated per / subject=pat(seq) type=CSH rcorr;
  ods output FitStatistics=FitCSH (rename=(value=CSH)) FitStatistics=FitCSHp; 
  title 'HETEROGENOUS COMPOUND SYMMETRY'; 
run; 
 
data fits; 
 merge FitCS FitAR1 FitUN FITCSH; 
 by descr; 
run; 
ods listing; title 'Summerized Fit Statistics'; run;
proc print data=fits; run;
 
/* Model Adjusting for carryover effects */
proc mixed data= FCS;
  class per seq drug pat;
  model FCS = per drug seq x1 x2/ddfm=kr;
  repeated per / subject=pat(seq) type=UN;
  store out_FCS;
 run;
 
proc plm restore=out_FCS;
  lsmeans drug / adjust=tukey plot=meanplot cl lines;
  ods exclude diffs diffplot;
run;
 
/* Reduced Model, Ignoring carryover effects */
proc mixed data= FCS;
  class per seq drug pat;
  model FCS = per drug seq/ddfm=kr;
  repeated per / subject=pat(seq) type=UN;
  lsmeans drug / pdiff adjust=tukey;
run;